labview写入一维数组到电子表格，如何做过第二次写入不覆盖第一次写入的数据

Posted 2023-05-04

就是第一次写入在第一行，第二次写入在第二行，网上说的"添加至新文件"给TURE根本就没有用，还是覆盖

参考技术A 使用寄存器，执行循环体

如何在每个时间步将大型数组（一维或二维）写入 hdf5 文件以在 Fortran 中进行模拟

【中文标题】如何在每个时间步将大型数组（一维或二维）写入 hdf5 文件以在 Fortran 中进行模拟

【英文标题】：How to write a large array (1D or 2D) to hdf5 file at each time step for a simulation in Fortran

【发布时间】：2019-02-19 19:06:01

【问题描述】：

我的模拟（用 Fortran 90 编写）在每个时间步生成一个数组（1D、2D 或 3D）。我想将这些数组输出到一个 HDF5 文件中，该文件包含为所有时间步生成的数组。请注意，由于每个时间步的输出数组具有相同的秩和维度，因此可以通过添加额外的时间维度将这些数组组合在一起。

现在，我只是创建一个缓冲区数组来组合每个时间步的输出数组，然后在模拟结束时将缓冲区数组写入 HDF5 文件中的数据集。但是如果每个时间步的输出数组变大，缓冲区只能保存几个时间步的数据。所以我需要每隔几个时间步将数据刷新到 HDF5。

我查看了许多帖子和文档，发现他们提到了一些技术，例如分块数据集和 hyperslab 选择，以有效地输出到 HDF5。但我仍然不确定如何将这些应用到我的案例中。有人可以给我一个 Fortran 90 的例子吗？

【问题讨论】：

欢迎，请使用 Welcome tour 并使用标签 fortran 解决所有 Fortran 问题。

【参考方案1】：

在阅读了一些关于 hyperslab 的文档后，我得到了在每个工作时间步写入 hdf5 文件的过程。以下是演示代码。希望对你有用。

program test_hyperslab
  use HDF5
  implicit none
  integer :: error  ! error flag

  character(len=9), parameter :: filename = "subset.h5"
  character(len=8), parameter :: dsetname = "IntArray"

  integer(HID_T) :: file_id    ! file identifier
  integer(HID_T) :: dset_id    ! dataset identifier
  integer(HID_T) :: dataspace  ! dataspace identifier
  integer(HID_T) :: memspace   ! memspace identifier

  integer(HSIZE_T), dimension(2) :: dimsm = (/3, 1/)
  integer, dimension(3) :: sdata    ! subset buffer
  integer :: dim0_sub = 3
  integer :: dim1_sub = 1
  integer(HSIZE_T), dimension(2) :: count = (/3, 1/)
  integer(HSIZE_T), dimension(2) :: offset
  integer(HSIZE_T), dimension(2) :: stride = (/1, 1/)
  integer(HSIZE_T), dimension(2) :: block = (/1, 1/)

  integer(HSIZE_T), dimension(2) :: dimsf = (/3, 10/)

  integer, dimension(3, 10) :: rdata    ! data to read

  integer :: rank = 2
  integer :: dim0 = 3
  integer :: dim1 = 10

  integer :: i

  ! initialize fortran interface
  call h5open_f(error)
  ! create a new file with default properties
  call h5fcreate_f(filename, H5F_ACC_TRUNC_F, file_id, error)
  ! create the data space for the dataset
  call h5screate_simple_f(rank, dimsf, dataspace, error)
  ! create the dataset with default properties
  call h5dcreate_f(file_id, dsetname, H5T_NATIVE_INTEGER, dataspace, &
    dset_id, error)
  ! create memory dataspace
  call h5screate_simple_f(rank, dimsm, memspace, error)

  offset(1) = 0
  do i = 1, 10
    offset(2) = i - 1
    sdata = i
    ! select subset
    call h5sselect_hyperslab_f(dataspace, H5S_SELECT_SET_F, &
      offset, count, error, stride, block)
    ! write subset to dataset
    call h5dwrite_f(dset_id, H5T_NATIVE_INTEGER, sdata, dimsm, error, &
      memspace, dataspace)
  enddo

  ! read entire dataset back
  call h5dread_f(dset_id, H5T_NATIVE_INTEGER, rdata, dimsf, error)
  write(*, '(A)') "Data in file after subset written: "
  do i = 1, dim0
    write(*, '(100(1X,I0,1X))') rdata(i, 1:dim1)
  enddo

  ! close everything opened
  call h5sclose_f(dataspace, error)
  call h5sclose_f(memspace, error)
  call h5dclose_f(dset_id, error)
  call h5fclose_f(file_id, error)

  ! close fortran interface
  call h5close_f(error)
end program test_hyperslab

【参考方案2】：

我认为您需要额外的库。

请在此处查看 Fortran 库的链接：https://support.hdfgroup.org/HDF5/doc/fortran/index.html 和此处的一些示例：https://support.hdfgroup.org/HDF5/examples/f-src.html

【讨论】：

您好 msi_gerva，您的链接指向我已经使用过的 hdf5 库。我只是不知道如何使它适用于我的情况，即如何在每个时间步有效地将一个大数组写入单个 hdf5 文件。