Groovy嵌入式Apache FTP服务器示例

Posted 2021-02-24

http://mina.apache.org/ftpserver/

#!/usr/bin/env groovy
 
// file: FtpSvr.groovy
 
/*
	Laurence Toenjes Jan 12, 2013
 
	Standalone Groovy ftp server script (no jars to download if Groovy is 
	properly installed).  
 
	The default user is guest with password of guest
	and the ftp home/base directory is the home folder of the account
	running this script.
	A root account is also created with the ftp home/base dir set to /
	and the password is root (for root to fully work you would obviously
	have to run it under an account with expanded file permissions).
 
	Optional command line args:
		arg0 defaults to port 8021.
		arg1 (ftp base dir) defaults to the home directory of the user running this script.
*/
 
// See http://mina.apache.org/ftpserver/ for more details.
 
// for OS X/*nix
//   don't forget to do: chmod +x FtpServer.groovy
//   also run as sudo ./FtpSvr.groovy for when using a port number < 1024
 
@Grapes([
	  @Grab(group='org.apache.ftpserver', module='ftpserver-core', version='1.0.6')
	, @Grab(group='ch.qos.logback', module='logback-classic', version='1.0.9')
])
 
import org.apache.ftpserver.FtpServerFactory;
import org.apache.ftpserver.FtpServer;
 
import org.apache.ftpserver.listener.ListenerFactory;
 
import org.apache.ftpserver.usermanager.PropertiesUserManagerFactory;
import org.apache.ftpserver.usermanager.SaltedPasswordEncryptor;
import org.apache.ftpserver.usermanager.impl.BaseUser;
 
import org.apache.ftpserver.ftplet.UserManager;
import org.apache.ftpserver.ftplet.Authority;
 
import org.apache.ftpserver.usermanager.impl.WritePermission;
 
import java.util.Properties;
 
public class FtpSvr {
 
	def go(String[] args) {
		String ftpUsersPropFileName = "FtpSvrUsers.properties"
		int    defaultPort = 8021
 
		String userHome = System.properties.'user.home';
		String homeDir = args.size()>=2 ? args[1].replace('~', userHome) : userHome ;
		assert new File(homeDir).exists();
 
		def gi = groovy.inspect.swingui.ObjectBrowser.&inspect; // for debug
 
		int port = args.size()>=1 ? args[0].toInteger() : defaultPort ;
		println "### ftp port   : $port"
		println "### ftp homeDir: $homeDir"
		println ''
 
		// the basics
		// FtpServerFactory serverFactory = new FtpServerFactory();
		// FtpServer server = serverFactory.createServer();
		// server.start();
 
		// setup users
 
		PropertiesUserManagerFactory userManagerFactory = new PropertiesUserManagerFactory();
 
		def myusersPropsFile = new File( ftpUsersPropFileName );
		if ( !myusersPropsFile.exists() ) {
			myusersPropsFile.createNewFile();
		}
 
		userManagerFactory.setFile( myusersPropsFile );
		userManagerFactory.setPasswordEncryptor(new SaltedPasswordEncryptor());
 
		UserManager um = userManagerFactory.createUserManager();
 
		def users = []
		users << [ uid:'guest', pwd:'guest', home:homeDir ]
		users << [ uid:'root' , pwd:'root' , home:'/'     ]
 
		def addUser = { map ->
			BaseUser user = new BaseUser();
			user.setName( map.uid );
			user.setPassword( map.pwd );
			user.setHomeDirectory( map.home );
 
			List<Authority> auths = new ArrayList<Authority>();
			Authority auth = new WritePermission();
			auths.add(auth);
			user.setAuthorities(auths);
			// gi user;
			// gi user.getAuthorities();
			um.save(user);
		}
 
		users.each { itUserMap -> addUser( itUserMap ) }
 
		FtpServerFactory serverFactory = new FtpServerFactory();
 
		serverFactory.setUserManager( um );
 
		ListenerFactory factory = new ListenerFactory();
 
		// set the port of the listener
		factory.setPort( port );
 
		// replace the default listener
		serverFactory.addListener("default", factory.createListener());
 
		// start the server
		FtpServer server = serverFactory.createServer(); 
 
		// groovy.inspect.swingui.ObjectBrowser.inspect( server );
		// groovy.inspect.swingui.ObjectBrowser.inspect( server.userManager );
		// gi server.userManager.getAllUserNames() as List;
 
		server.start();
	}
 
	public static void main(String[] args) {
		def mo = new FtpSvr();
		mo.go(args)
	}
}