Proteus VSM Studio汇编 + 8位数码管+按键扫描

Posted 2022-05-31 perseverance52

Proteus VSM Studio汇编 + 8位数码管+按键扫描

---

• Proteus构建演示
  

基于Proteus VSM Studio汇编代码（.asm）

;**************************************
;以下8个存储单元分别存放8位数码管的段码
LED_BIT_1	EQU		30H
LED_BIT_2	EQU		31H
LED_BIT_3	EQU		32H
LED_BIT_4	EQU		33H
LED_BIT_5	EQU		34H
LED_BIT_6	EQU		35H
LED_BIT_7	EQU		36H
LED_BIT_8	EQU		37H
T_COUNT		EQU		38H
KEY_CNT		EQU		39H
LINE		EQU		3AH
ROW			EQU		3BH
VAL			EQU		3CH
;**************************************
		ORG		00H
		SJMP	START
		ORG		0BH
		LJMP	INT_T0
START:	MOV		T_COUNT,#00H	;初始化
		MOV		KEY_CNT,#00H
		MOV		LINE,#00H
		MOV		ROW,#00H
		MOV		VAL,#00H
		MOV		LED_BIT_1,#00H
		MOV		LED_BIT_2,#00H
		MOV		LED_BIT_3,#00H
		MOV		LED_BIT_4,#00H
		MOV		LED_BIT_5,#00H
		MOV		LED_BIT_6,#00H
		MOV		LED_BIT_7,#00H
		MOV		LED_BIT_8,#3FH
		MOV		DPTR,#TABLE
A0:		LCALL	DISP
;**************************************
;按键扫描
LSCAN:	MOV		P3,#0F0H		;行码扫描
	L1:	JNB		P3.0,L2
		LCALL	DELAY
		JNB		P3.0,L2
		MOV		LINE,#00H
		LJMP	RSCAN
	L2:	JNB		P3.1,L3
		LCALL	DELAY
		JNB		P3.1,L3
		MOV		LINE,#01H
		LJMP	RSCAN
	L3:	JNB		P3.2,L4
		LCALL	DELAY
		JNB		P3.2,L4
		MOV		LINE,#02H
		LJMP	RSCAN
	L4:	JNB		P3.3,A0
		LCALL	DELAY
		JNB		P3.3,A0
		MOV		LINE,#03H

RSCAN:	MOV		P3,#0FH			;列码扫描
	C1:	JNB		P3.4,C2
		MOV		ROW,#00H
		LJMP	CALCU
	C2:	JNB		P3.5,C3
		MOV		ROW,#01H
		LJMP	CALCU
	C3:	JNB		P3.6,C4
		MOV		ROW,#02H
		LJMP	CALCU
	C4:	JNB		P3.7,C1
		MOV		ROW,#03H		
;***********************************************
CALCU:	INC		KEY_CNT			;统计按键次数
		MOV		A,KEY_CNT


		CJNE	A,#9,K1			;如果按键9次,发声提示
		MOV		TMOD,#01H
		MOV		TH0,#(65536-700)/256
		MOV		TL0,#(65536-700)MOD	256
		MOV		IE,#82H
		SETB	TR0

	W10:MOV		A,P3		;等待按键抬起
		CJNE	A,#0FH,W11
		MOV		P0,#00H
		CLR		TR0
		LJMP	START
	W11:MOV		A,P3
		CJNE	A,#0F0H,W12
		MOV		P0,#00H
		CLR		TR0
		LJMP	START
	W12:SJMP	W10

;**************************************************
;第1次按键,清除已显示的0,显示按下的数字
	K1:	CJNE	A,#1,K2			
		MOV		A,LINE
		MOV		B,#04H
		MUL		AB
		ADD		A,ROW
		MOV		VAL,A
		MOVC	A,@A+DPTR
		MOV		LED_BIT_8,A
DISP1:	LCALL	DISP

	W20:MOV		A,P3		;等待按键抬起
		CJNE	A,#0FH,W21
		LJMP	A0
	W21:MOV		A,P3
		CJNE	A,#0F0H,W22
		LJMP	A0
	W22:SJMP	DISP1			
;***************************************************
;第2到8次按键,移位显示按下的数字
	K2:	MOV		A,LINE
		MOV		B,#04H
		MUL		AB
		ADD		A,ROW
		MOV		VAL,A
		MOVC	A,@A+DPTR
		LCALL	SHIFT	   	;调用段码移位
DISP2:	LCALL	DISP

	W30:MOV		A,P3		;等待按键抬起
		CJNE	A,#0FH,W31
		LJMP	A0
	W31:MOV		A,P3
		CJNE	A,#0F0H,W32
		LJMP	A0
	W32:SJMP	DISP2				


;****************************************
;定时器0中断服务程序,驱动扬声器发声
INT_T0:	MOV		TH0,#(65536-700)/256
		MOV		TL0,#(65536-700)MOD	256
		CPL		P1.0
		RETI
;****************************************
;段码移位子程序
SHIFT:	MOV		LED_BIT_1,LED_BIT_2
		MOV		LED_BIT_2,LED_BIT_3
		MOV		LED_BIT_3,LED_BIT_4
		MOV		LED_BIT_4,LED_BIT_5
		MOV		LED_BIT_5,LED_BIT_6
		MOV		LED_BIT_6,LED_BIT_7
		MOV		LED_BIT_7,LED_BIT_8
		MOV		LED_BIT_8,A
		RET
;****************************************
;显示控制子程序
DISP:	CLR		P2.7
		MOV		P0,LED_BIT_8
		LCALL	DELAY
		SETB	P2.7
		CLR		P2.6
		MOV		P0,LED_BIT_7
		LCALL	DELAY
		SETB	P2.6
		CLR		P2.5
		MOV		P0,LED_BIT_6
		LCALL	DELAY
		SETB	P2.5
		CLR		P2.4
		MOV		P0,LED_BIT_5
		LCALL	DELAY
		SETB	P2.4
		CLR		P2.3
		MOV		P0,LED_BIT_4
		LCALL	DELAY
		SETB	P2.3
		CLR		P2.2
		MOV		P0,LED_BIT_3
		LCALL	DELAY
		SETB	P2.2
		CLR		P2.1
		MOV		P0,LED_BIT_2
		LCALL	DELAY
		SETB	P2.1
		CLR		P2.0
		MOV		P0,LED_BIT_1
		LCALL	DELAY
		SETB	P2.0
		RET

DELAY:	MOV		R6,#10
D1:		MOV		R7,#250
		DJNZ	R7,$
		DJNZ	R6,D1
		RET

TABLE: 	DB 		3FH,06H,5BH,4FH,66H,6DH,7DH,07H
		DB 		7FH,6FH,77H,7CH,39H,5EH,79H,71H
		END

仿真资源和程序源码

本实验基于Proteus8.9SP2平台，保留Keil 外部编译工程

链接：https://pan.baidu.com/s/1Y4I1D5TGzto-bSs6TnBkCg 
提取码：5d9i