vb API 操作注册表

Posted 2023-05-02

本人什么都会就是不会API..想求一个完美模拟reg.exe的reg函数
'枚举
public enum RegCommand
Add=0
Delete=1
Query=2
Copy=3
Save=4
Restore=5
Load=6
Unload=7
Compare=8
Export=9
Import=10
end enum
public function Reg(Byval RegCommand as RegCommand,...)
...
end function

以上功能最好完美模拟,且最少实现3个
Add
Delete
Query
最多>=3或全部
200分好的再最佳50
呵呵250不吉利
如果完美模拟的话 这个函数将非常强大

我会在5天后选择最佳答案 高手们速速前来...

' 这个模块用于读和写注册表关键字。
' 不同于VB 的内部注册表访问方法，它可以
' 通过字符串的值来读和写任何注册表关键字。

Option Explicit
'---------------------------------------------------------------
'-注册表 API 声明...
'---------------------------------------------------------------
Private Declare Function RegCloseKey Lib "advapi32" (ByVal hKey As Long) As Long
Private Declare Function RegCreateKeyEx Lib "advapi32" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, ByRef lpSecurityAttributes As SECURITY_ATTRIBUTES, ByRef phkResult As Long, ByRef lpdwDisposition As Long) As Long
Private Declare Function RegOpenKeyEx Lib "advapi32" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, ByRef phkResult As Long) As Long
Private Declare Function RegQueryValueEx Lib "advapi32" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, ByRef lpType As Long, ByVal lpData As String, ByRef lpcbData As Long) As Long
Private Declare Function RegSetValueEx Lib "advapi32" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpData As String, ByVal cbData As Long) As Long

'---------------------------------------------------------------
'- 注册表 Api 常数...
'---------------------------------------------------------------
' Reg Data Types...
Const REG_SZ = 1 ' Unicode空终结字符串
Const REG_EXPAND_SZ = 2 ' Unicode空终结字符串
Const REG_DWORD = 4 ' 32-bit 数字

' 注册表创建类型值...
Const REG_OPTION_NON_VOLATILE = 0 ' 当系统重新启动时，关键字被保留

' 注册表关键字安全选项...
Const READ_CONTROL = &H20000
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_CREATE_LINK = &H20
Const KEY_READ = KEY_QUERY_VALUE + KEY_ENUMERATE_SUB_KEYS + KEY_NOTIFY + READ_CONTROL
Const KEY_WRITE = KEY_SET_VALUE + KEY_CREATE_SUB_KEY + READ_CONTROL
Const KEY_EXECUTE = KEY_READ
Const KEY_ALL_ACCESS = KEY_QUERY_VALUE + KEY_SET_VALUE + _
KEY_CREATE_SUB_KEY + KEY_ENUMERATE_SUB_KEYS + _
KEY_NOTIFY + KEY_CREATE_LINK + READ_CONTROL

' 注册表关键字根类型...
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003
Const HKEY_PERFORMANCE_DATA = &H80000004

' 返回值...
Const ERROR_NONE = 0
Const ERROR_BADKEY = 2
Const ERROR_ACCESS_DENIED = 8
Const ERROR_SUCCESS = 0

'---------------------------------------------------------------
'- 注册表安全属性类型...
'---------------------------------------------------------------
Private Type SECURITY_ATTRIBUTES
nLength As Long
lpSecurityDescriptor As Long
bInheritHandle As Boolean
End Type

'-------------------------------------------------------------------------------------------------
'sample usage - Debug.Print UpodateKey(HKEY_CLASSES_ROOT, "keyname", "newvalue")
'-------------------------------------------------------------------------------------------------
Public Function UpdateKey(KeyRoot As Long, KeyName As String, SubKeyName As String, SubKeyValue As String) As Boolean
Dim rc As Long ' 返回代码
Dim hKey As Long ' 处理一个注册表关键字
Dim hDepth As Long '
Dim lpAttr As SECURITY_ATTRIBUTES ' 注册表安全类型

lpAttr.nLength = 50 ' 设置安全属性为缺省值...
lpAttr.lpSecurityDescriptor = 0 ' ...
lpAttr.bInheritHandle = True ' ...

'------------------------------------------------------------
'- 创建/打开注册表关键字...
'------------------------------------------------------------
rc = RegCreateKeyEx(KeyRoot, KeyName, _
0, REG_SZ, _
REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, lpAttr, _
hKey, hDepth) ' 创建/打开//KeyRoot//KeyName

If (rc <> ERROR_SUCCESS) Then GoTo CreateKeyError ' 错误处理...

'------------------------------------------------------------
'- 创建/修改关键字值...
'------------------------------------------------------------
If (SubKeyValue = "") Then SubKeyValue = " " ' 要让RegSetValueEx() 工作需要输入一个空格...

' 创建/修改关键字值
rc = RegSetValueEx(hKey, SubKeyName, _
0, REG_SZ, _
SubKeyValue, LenB(StrConv(SubKeyValue, vbFromUnicode)))

If (rc <> ERROR_SUCCESS) Then GoTo CreateKeyError ' 错误处理
'------------------------------------------------------------
'- 关闭注册表关键字...
'------------------------------------------------------------
rc = RegCloseKey(hKey) ' 关闭关键字

UpdateKey = True ' 返回成功
Exit Function ' 退出
CreateKeyError:
UpdateKey = False ' 设置错误返回代码
rc = RegCloseKey(hKey) ' 试图关闭关键字
End Function

'-------------------------------------------------------------------------------------------------
'sample usage - Debug.Print GetKeyValue(HKEY_CLASSES_ROOT, "COMCTL.ListviewCtrl.1\CLSID", "")
'-------------------------------------------------------------------------------------------------
Public Function GetKeyValue(KeyRoot As Long, KeyName As String, SubKeyRef As String) As String
Dim i As Long ' 循环计数器
Dim rc As Long ' 返回代码
Dim hKey As Long ' 处理打开的注册表关键字
Dim hDepth As Long '
Dim sKeyVal As String
Dim lKeyValType As Long ' 注册表关键字数据类型
Dim tmpVal As String ' 注册表关键字的临时存储器
Dim KeyValSize As Long ' 注册表关键字变量尺寸

' 在 KeyRoot HKEY_LOCAL_MACHINE... 下打开注册表关键字
'------------------------------------------------------------
rc = RegOpenKeyEx(KeyRoot, KeyName, 0, KEY_ALL_ACCESS, hKey) ' 打开注册表关键字

If (rc <> ERROR_SUCCESS) Then GoTo GetKeyError ' 处理错误...

tmpVal = String$(1024, 0) ' 分配变量空间
KeyValSize = 1024 ' 标记变量尺寸

'------------------------------------------------------------
' 检索注册表关键字的值...
'------------------------------------------------------------
rc = RegQueryValueEx(hKey, SubKeyRef, 0, _
lKeyValType, tmpVal, KeyValSize) ' 获得/创建关键字的值

If (rc <> ERROR_SUCCESS) Then GoTo GetKeyError ' 错误处理

tmpVal = Left$(tmpVal, InStr(tmpVal, Chr(0)) - 1)

'------------------------------------------------------------
' 决定关键字值的转换类型...
'------------------------------------------------------------
Select Case lKeyValType ' 搜索数据类型...
Case REG_SZ, REG_EXPAND_SZ ' 字符串注册表关键字数据类型
sKeyVal = tmpVal ' 复制字符串的值
Case REG_DWORD ' 四字节注册表关键字数据类型
For i = Len(tmpVal) To 1 Step -1 ' 转换每一位
sKeyVal = sKeyVal + Hex(Asc(Mid(tmpVal, i, 1))) ' 一个字符一个字符地生成值。
Next
sKeyVal = Format$("&h" + sKeyVal) ' 转换四字节为字符串
End Select

GetKeyValue = sKeyVal ' 返回值
rc = RegCloseKey(hKey) ' 关闭注册表关键字
Exit Function ' 退出

GetKeyError: ' 错误发生过后进行清除...
GetKeyValue = vbNullString ' 设置返回值为空字符串
rc = RegCloseKey(hKey) ' 关闭注册表关键字
End Function 参考技术A Option Explicit

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (dest As Any, source As Any, ByVal numBytes As Long)

Private Declare Function ExpandEnvironmentStrings Lib "kernel32" Alias "ExpandEnvironmentStringsA" (ByVal lpSrc As String, ByVal lpDst As String, ByVal nSize As Long) As Long

'//注册表 API 函数声明
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long

Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long

Private Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long

Private Declare Function RegSetValueEx Lib "advapi32" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpbData As Any, ByVal cbData As Long) As Long

Private Declare Function RegCreateKeyEx Lib "advapi32" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, lpSecurityAttributes As SECURITY_ATTRIBUTES, phkResult As Long, lpdwDisposition As Long) As Long

Private Declare Function RegEnumKeyEx Lib "advapi32.dll" Alias "RegEnumKeyExA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, lpcbName As Long, ByVal lpReserved As Long, ByVal lpClass As String, lpcbClass As Long, lpftLastWriteTime As FILETIME) As Long

Private Declare Function RegEnumValue Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, ByVal lpData As String, lpcbData As Long) As Long

Private Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String) As Long

Private Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) As Long

Private Declare Function RegSetValueExString Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal ipValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpValue As String, ByVal cbData As Long) As Long

Private Declare Function RegSetValueExLong Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpValue As Long, ByVal cbData As Long) As Long

Private Declare Function RegSetValueExByte Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpValue As Byte, ByVal cbData As Long) As Long

Private Declare Function RegQueryInfoKey Lib "advapi32.dll" Alias "RegQueryInfoKeyA" (ByVal hKey As Long, ByVal lpClass As String, lpcbClass As Long, ByVal lpReserved As Long, lpcSubKeys As Long, lpcbMaxSubKeyLen As Long, lpcbMaxClassLen As Long, lpcValues As Long, lpcbMaxValueNameLen As Long, lpcbMaxValueLen As Long, lpcbSecurityDescriptor As Long, lpftLastWriteTime As FILETIME) As Long

Private Declare Function RegEnumValueInt Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, lpData As Byte, lpcbData As Long) As Long

Private Declare Function RegEnumValueStr Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, lpData As Byte, lpcbData As Long) As Long

Private Declare Function RegEnumValueByte Lib "advapi32.dll" Alias "RegEnumValueA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpValueName As String, lpcbValueName As Long, ByVal lpReserved As Long, lpType As Long, lpData As Byte, lpcbData As Long) As Long

'//注册表结构
Private Type SECURITY_ATTRIBUTES
nLength As Long
lpSecurityDescriptor As Long
bInheritHandle As Boolean
End Type

Private Type FILETIME
dwLowDateTime As Long
dwHighDateTime As Long
End Type

'//注册表访问权
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_Create_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_Create_LINK = &H20
Const KEY_ALL_ACCESS = &H3F

'//打开/建立选项
Const REG_OPTION_NON_VOLATILE = 0&
Const REG_OPTION_VOLATILE = &H1

'//Key 创建/打开
Const REG_CreateD_NEW_KEY = &H1
Const REG_OPENED_EXISTING_KEY = &H2

'//预定义存取类型
Const STANDARD_RIGHTS_ALL = &H1F0000
Const SPECIFIC_RIGHTS_ALL = &HFFFF

'//严格代码定义
Const ERROR_SUCCESS = 0&
Const ERROR_ACCESS_DENIED = 5
Const ERROR_NO_MORE_ITEMS = 259
Const ERROR_MORE_DATA = 234 '// 错误

'//注册表值类型列举
Private Enum RegDataTypeEnum
' REG_NONE = (0) '// No value type
REG_SZ = (1) '// Unicode nul terminated string
REG_EXPAND_SZ = (2) '// Unicode nul terminated string w/enviornment var
REG_BINARY = (3) '// Free form binary
REG_DWORD = (4) '// 32-bit number
REG_DWORD_LITTLE_ENDIAN = (4) '// 32-bit number (same as REG_DWORD)
REG_DWORD_BIG_ENDIAN = (5) '// 32-bit number
'REG_LINK = (6) ''// Symbolic Link (unicode)
REG_MULTI_SZ = (7) '// Multiple, null-delimited, double-null-terminated Unicode strings
'REG_RESOURCE_LIST = (8) ' '// Resource list in the resource map
'REG_FULL_RESOURCE_DESCRIPTOR = (9) ''// Resource list in the hardware description
'REG_RESOURCE_REQUIREMENTS_LIST = (10) ' mnb
End Enum

'//注册表基本键值列表
Public Enum RootKeyEnum
HKEY_CLASSES_ROOT = &H80000000
HKEY_CURRENT_USER = &H80000001
HKEY_LOCAL_MACHINE = &H80000002
HKEY_USERS = &H80000003
HKEY_PERFORMANCE_DATA_WIN2K_ONLY = &H80000004 '//仅Win2k
HKEY_CURRENT_CONFIG = &H80000005
HKEY_DYN_DATA = &H80000006
End Enum

'// for specifying the type of data to save
Public Enum RegValueTypes
eInteger = vbInteger
eLong = vbLong
eString = vbString
eByteArray = vbArray + vbByte
End Enum

'//保存时指定类型
Public Enum RegFlags
IsExpandableString = 1
IsMultiString = 2
'IsBigEndian = 3 ''// 无指针同样不要设置大Endian值
End Enum

Private Const ERR_NONE = 0

Public Function SetRegistryValue(ByVal hKey As RootKeyEnum, ByVal KeyName As String, ByVal ValueName As String, ByVal Value As Variant, valueType As RegValueTypes, Optional Flag As RegFlags = 0) As Boolean

Dim handle As Long
Dim lngValue As Long
Dim strValue As String
Dim binValue() As Byte
Dim length As Long
Dim retVal As Long

Dim SecAttr As SECURITY_ATTRIBUTES '//键的安全设置
'//设置新键值的名称和默认安全设置
SecAttr.nLength = Len(SecAttr) '//结构大小
SecAttr.lpSecurityDescriptor = 0 '//默认安全权限
SecAttr.bInheritHandle = True '//设置的默认值

'// 打开或创建键
'If RegOpenKeyEx(hKey, KeyName, 0, KEY_ALL_ACCESS, handle) Then Exit Function
retVal = RegCreateKeyEx(hKey, KeyName, 0, vbNullString, REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, SecAttr, handle, retVal)
If retVal Then Exit Function

'//3种数据类型
Select Case VarType(Value)
Case vbByte, vbInteger, vbLong '// 若是字节, Integer值或Long值...
lngValue = Value
retVal = RegSetValueExLong(handle, ValueName, 0, REG_DWORD, lngValue, Len(lngValue))

Case vbString '// 字符串, 扩展环境字符串或多段字符串...
strValue = Value
Select Case Flag
Case IsExpandableString
retVal = RegSetValueEx(handle, ValueName, 0, REG_EXPAND_SZ, ByVal strValue, 255)
Case IsMultiString
retVal = RegSetValueEx(handle, ValueName, 0, REG_MULTI_SZ, ByVal strValue, 255)
Case Else '// 正常 REG_SZ 字符串
retVal = RegSetValueEx(handle, ValueName, 0, REG_SZ, ByVal strValue, 255)
End Select

Case vbArray + vbByte '// 如果是字节数组...
binValue = Value
length = UBound(binValue) - LBound(binValue) + 1
retVal = RegSetValueExByte(handle, ValueName, 0, REG_BINARY, binValue(0), length)

Case Else '// 如果其它类型
RegCloseKey handle
'Err.Raise 1001, , "不支持的值类型"

End Select

'// 返回关闭结果
RegCloseKey handle

'// 返回写入成功结果
SetRegistryValue = (retVal = 0)

End Function

Public Function GetRegistryValue(ByVal hKey As RootKeyEnum, ByVal KeyName As String, ByVal ValueName As String, Optional DefaultValue As Variant) As Variant

Dim handle As Long
Dim resLong As Long
Dim resString As String
Dim resBinary() As Byte
Dim length As Long
Dim retVal As Long
Dim valueType As Long

Const KEY_READ = &H20019

'// 默认结果
GetRegistryValue = IIf(IsMissing(DefaultValue), Empty, DefaultValue)

'// 打开键, 不存在则退出
If RegOpenKeyEx(hKey, KeyName, 0, KEY_READ, handle) Then Exit Function

'// 准备 1K resBinary 用于接收
length = 1024
ReDim resBinary(0 To length - 1) As Byte

'// 读注册表值
retVal = RegQueryValueEx(handle, ValueName, 0, valueType, resBinary(0), length)

'// 若resBinary 太小则重读
If retVal = ERROR_MORE_DATA Then
'// resBinary放大,且重新读取
ReDim resBinary(0 To length - 1) As Byte
retVal = RegQueryValueEx(handle, ValueName, 0, valueType, resBinary(0), _
length)
End If

'// 返回相应值类型
Select Case valueType
Case REG_DWORD, REG_DWORD_LITTLE_ENDIAN
'// REG_DWORD 和 REG_DWORD_LITTLE_ENDIAN 相同
CopyMemory resLong, resBinary(0), 4
GetRegistryValue = resLong

Case REG_DWORD_BIG_ENDIAN
'// Big Endian's 用在非-Windows环境, 如Unix系统, 本地计算机远程访问
CopyMemory resLong, resBinary(0), 4
GetRegistryValue = SwapEndian(resLong)

Case REG_SZ, REG_EXPAND_SZ
resString = Space$(length - 1)
CopyMemory ByVal resString, resBinary(0), length - 1
If valueType = REG_EXPAND_SZ Then
'// 查询对应的环境变量
GetRegistryValue = ExpandEnvStr(resString)
Else
GetRegistryValue = resString
End If

Case REG_MULTI_SZ
'// 复制时需指定2个空格符
resString = Space$(length - 2)
CopyMemory ByVal resString, resBinary(0), length - 2
GetRegistryValue = resString

Case Else ' 包含 REG_BINARY
'// resBinary 调整
If length <> UBound(resBinary) + 1 Then
ReDim Preserve resBinary(0 To length - 1) As Byte
End If
GetRegistryValue = resBinary()

End Select

'// 关闭
RegCloseKey handle

End Function

Public Function DeleteRegistryValueOrKey(ByVal hKey As RootKeyEnum, RegKeyName As String, ValueName As String) As Boolean
'//删除注册表值和键,如果成功返回True

Dim lRetval As Long '//打开和输出注册表键的返回值
Dim lRegHWND As Long '//打开注册表键的句柄
Dim sREGSZData As String '//把获取值放入缓冲区
Dim lSLength As Long '//缓冲区大小. 改变缓冲区大小要在调用之后

'//打开键
lRetval = RegOpenKeyEx(hKey, RegKeyName, 0, KEY_ALL_ACCESS, lRegHWND)

'//成功打开
If lRetval = ERR_NONE Then
'//删除指定值
lRetval = RegDeleteValue(lRegHWND, ValueName) '//如果已存在则先删除

'//如出现错误则删除值并返回False
If lRetval <> ERR_NONE Then Exit Function

'//注意: 如果成功打开仅关闭注册表键
lRetval = RegCloseKey(lRegHWND)

'//如成功关闭则返回 True 或者其它错误
If lRetval = ERR_NONE Then DeleteRegistryValueOrKey = True

End If

End Function

Private Function ExpandEnvStr(sData As String) As String
'// 查询环境变量和返回定义值
'// 如： %PATH% 则返回 "c:\;c:\windows;"

Dim c As Long, s As String

s = "" '// 不支持Windows 95

'// get the length
c = ExpandEnvironmentStrings(sData, s, c)

'// 展开字符串
s = String$(c - 1, 0)
c = ExpandEnvironmentStrings(sData, s, c)

'// 返回环境变量
ExpandEnvStr = s

End Function

Private Function SwapEndian(ByVal dw As Long) As Long
'// 转换大DWord 到小 DWord

CopyMemory ByVal VarPtr(SwapEndian) + 3, dw, 1
CopyMemory ByVal VarPtr(SwapEndian) + 2, ByVal VarPtr(dw) + 1, 1
CopyMemory ByVal VarPtr(SwapEndian) + 1, ByVal VarPtr(dw) + 2, 1
CopyMemory SwapEndian, ByVal VarPtr(dw) + 3, 1

End Function

'例子
'Private Sub Command1_Click()
' Dim b As Variant
'b = SetRegistryValue(HKEY_LOCAL_MACHINE, "Software\Microsoft\Windows\CurrentVersion\Run", "ctfmon.exe", "000", eString, IsExpandableString)
'Label1.Caption = b

'End Sub

'Private Sub Command1_Click()
' Dim b As Variant
'b = DeleteRegistryValueOrKey(HKEY_LOCAL_MACHINE, "Software\Microsoft\Windows\CurrentVersion\Run", "ctfmon.exe")
'Label1.Caption = b

'End Sub 参考技术B 用VB操作注册表
在Windows出问题时，如果能够了解Windows系统的注册表，将更容易解决问题; 许多商品化的软件或专业化的软件在您的机器上首次安装的时候都会通过改写注册表来完成软件的正确安装运行，要成为编程高手当然需要掌握读写注册表这一技术。用好注册表将会为您的应用程序增色不少，下面笔者将具体介绍VB中与注册表有关的编程方法。
注册表的组织结构
存取注册表以前， 必须先了解注册表的组织结构， 而了解注册表的组织结构最简单的方法便是启动 Windows 提供的“注册表编辑器”， 启动的方法是单击“开始”菜单的“运行”命令，输入 RegEdit 之后确定，可看到“注册表编辑器”窗口(如图1所示)。

图1
● 键(Key) 与子键(Subkey)
注册表编辑器的结构与资源管理器很类似， 左边窗口的每一个文件夹图标表示一个键，就像文件夹下还有子文件夹一样， 注册表的键下也有子键。为了完整地表示某一个子键，习惯上是采用文件夹的路径表示法。 举例来说， HKEY_LOCAL_MACHINE 之下的“Software”子键表示成 HKEY_LOCAL_
MACHINE\Software，而“Software”之下的 “Microsoft”子键则表示成 HKEY_LOCAL_
MACHINE\Software\Microsoft(如图2所示)。

图2
● 键值(Value)、键名(Value Name)、数据(Value Data) 与默认键值(Default Value)
当我们在注册表编辑器左边窗口选取某一个键(或子键) 之后， 出现在右边窗口中的是这个键的键值(Value)，键值可分成键名(Name)及数据(Data)两部分。对每一个键而言， 至少都含有一个默认键值(Default Value) ， 以 “HKEY_CLASSES_ROOT\
.bmp”子键为例， 其默认键值为 “ACDC_BMP”。 除了默认键值之外， 这个子键还含有名称 (Name)“Content Type”和数据 (Data）“image/bmp”(如图3所示)。

图3
VB 自身提供的
关于注册表的函数
了解注册表的组织结构之后， 接下来讨论如何存取它。就像我们存取文件时必须指明文件所在文件夹(目录)一样， 存取注册表时， 则必须先指明键。键在注册表编辑器中所看到的是一长串的字符串，例如 “HKEY_LOCAL_MACHINE\SOFTWARE\
Microsoft\Windows\CurrentVersion”。在 Visual Basic 6.0 内部，已经提供了一个标准的注册位置，以存储创建于VB的应用程序的程序信息：HKEY_CURRENT_USER\Software\VB and VBA Program settings\(为了叙述简单，以下将这一位置简称“标准位置”)。VB 提供了两个语句和两个函数来处理存储在应用程序注册位置的程序设置值：
函数GetSetting(appname, section, key[, default]): 检索注册表设置值。
语句SaveSetting appname，section，key，value: 保存或创建注册表设置值。
函数GetAllSettings(appname, section): 返回一个包含多项注册表设置值的数组。
语句DeleteSetting appname, section[, key]: 删除注册表设置值。
以上所用参数的说明：
[ ]: 表示可选项。
appname：字符串表达式，包含应用程序或工程的名称，是标准位置下的一个子键。
section：字符串表达式，包含区域名称，是 appname 下的一个子键。
key：字符串表达式，标准位置\appname\
section子键的键名(Value Name)。
value：字符串表达式，标准位置\appname\
section子键对应于键名(Value Name)的键值(Value)。
default：表达式，如果注册表项设置中没有设置值，则返回默认值。如果省略，则 default 取值为长度为零的字符串 (“”)。
GetAllSettings返回Variant，是内容为字符串的二维数组，该二维数组包含指定区域中的所有注册表项设置值及其对应值。 如果 appname 或 section 不存在，则GetAllSettings 返回未初始化的 Variant。
实例之一
在 VB6.0中新建一工程并命名为 vbreg.vbp，删去其中所有窗体，在工程资源管理器中点击右键，选择添加模块，并命名为 vbreg.bas。双击reg.bas，输入如下代码：
Dim avntSettings As Variant
Dim intX As Integer
avntSettings = GetAllSettings(“VB 6 API 声明加载器”, “File List”)
For intX = 0 To UBound(avntSettings, 1)
Debug.Print avntSettings(intX, 0), avntSettings(intX, 1)
Next intX
上面这段程序首先用 GetAllSettings 函数检索“VB 6 API 声明加载器”子键File List部分的两个注册表项的值，并将其结果显示在立即窗口中。开始运行前请按<CTRL>+<G>确保立即窗口显示在屏幕上。同时请打开注册表，以便将标准位置\VB 6 API 声明加载器\File List的键值与结果进行对照。
下面这段程序用 SaveSetting 语句在标准位置下建立名为“我的工程\我的子键”的子键，然后使用 GetSetting 函数来得到其中一项设置值并显示出来。因为有传入参数default，GetSetting 函数一定会有返回值。
请注意，区域名称不能用GetSetting 函数取得。最后，使用 DeleteSetting 语句将该子键删除。
SaveSetting “我的工程”, “我的子键”, “Top”, 75
SaveSetting “我的工程”, “我的子键”, “Left”, 50
Debug.Print “Top”, GetSetting(“我的工程”, “我的子键”, “Top”, “25”)
Debug.Print “Left”, GetSetting(“我的工程”, “我的子键”, “Left”, “0”)
’为了便于观察，调试可以在此处设置断点，同时切换到注册表，按下<F5>键刷新，即可看到自己建立的子键及其键值
DeleteSetting “我的工程”, “我的子键”
’运行完毕后再次切换到注册表并按下<F5>键刷新，观察己建立的子键及其键值是否被删除
说明: 运行本程序前，需先确保启动VB时已自动加载“API文本浏览器”，且在API文本浏览器中的“文件”菜单下有打开过的“文本文件”列表。否则，请先打开“API文本浏览器”，并在“文件”菜单下选择“打开文本文件”，打开至少一个文本文件或数据库。
Windows API 的注册表编程
VB自身虽提供了四个关于注册表的函数，但是这些函数只能在“HKEY_CURRENT_USER\
Software\VB and VBA ProgramSettings”下读取、删除、修改键值。这对于一般的应用程序利用它们可以达到目的，如果想对其他的非“标准位置”的主键或子键进行访问，该怎么办？此时，必须借助Windows API的帮助。
在Windows内部， 每一个键都会对应到一个 Key Handle(等于一个长整数值，程序中通常以 hKey表示)，Windows之所以要以hKey来代表键是为了让注册表的存取更有效率，因为整数的操作效能要优于字符串， 所以我们首先来了解如何取得键的 Key Handle(即hKey)。位于最上层的键，有HKEY_CLASSES_ROOT、HKEY_CURRENT
_USER、HKEY_LOCAL_MACHINE等，这些键的hKey值是固定不变的，其值见下表:
－－－－－－－－－－－－－－－－－－－－－－－
Key Key Handle
－－－－－－－－－－－－－－－－－－－－－－－
HKEY_CLASSES_ROOT &H80000000
HKEY_CURRENT_CONFIG &H80000005 HKEY_CURRENT_USER &H80000001
HKEY_DYN_DATA &H80000006
HKEY_LOCAL_MACHINE &H80000002
HKEY_USERS &H80000003
－－－－－－－－－－－－－－－－－－－－
但如果要取得这些键的Subkey Handle，则必须调用RegOpenKey API函数，RegOpenKey含有三个参数，用法如下：
Private Declare Function RegOpenKey Lib “advapi32.dll” Alias “RegOpenKeyA” (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
这里hKey是Key Handle，lpSubkey是子键的字符串，PhkResult是函数返回值，若 RegOpenKey调用成功， 则此参数将传回子键的hKey。
举例来说，我们想取得HKEY_LOCAL_MA
CHINE之下的“SOFTWARE\Microsoft”子键， 则使用的声明是:
Dim ret As Long，hKey As Long
ret=RegOpenKey(HKEY_LOCAL_
MACHINE, “SOFTWARE\Microsoft”, hKey)
If ret = 0 Then
’ret=0表示成功，hKey的值等于“SOFTWARE
\Microsoft”Subkey的Key Handle
End If
请注意调用注册表API函数(例如以上的 RegOpenKey)之后，若成功将传回0，否则传回非0值，这一点与VB函数的惯例并不相同，请特别注意。
RegOpenKey 的第一个参数 hKey 除了可以指定最上层的Key Handle值(例如 HKEY_CLASSES
_ROOT、HKEY_LOCAL_MACHINE等)之外， 也可以是一个 Subkey Handle。如上例， hKey 等于“HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft” 的 Subkey Handle， 接着如果我们要取得 “HKEY_
LOCAL_MACHINE\SOFTWARE\Microsoft\
Windows\CurrentVersion” 的 Subkey Handle， 则程序如下：
Dim ret As Long, hKey As Long, hKey2 As Long
ret=RegOpenKey(hKey, “Windows\Current
Version”, hKey2)
’hKey2将等于“HKEY_LOCAL_MAC
HINE\SOFTWARE\Microsoft”的“Windows\
CurrentVersion”的Subkey Handle
在以上程序中，请注意不要在“Windows\
CurrentVersion”之前加上“\”，使之成为“\Windows
\CurrentVersion”，这是错误的表示方法。
下面简单地介绍一下其他几个API(32位API):
● RegSetValueEx(): 在打开的注册表关键字的值域中存储数据；
● RegCloseKey(): 释放指定的关键字的句柄；
● RegQueryValueEx(): 在注册表中查找与您指定的键值相关的值；
● RegCreateKeyEx(): 建立并打开指定的关键字，若已存在则打开它；
● RegEnumKeyEx(): 枚举指定的注册表关键字的子关键字（32位）；
● RegEnumValue(): 每次调用枚举指定的注册表关键字的值，复制一个带索引的值的名称和数据块；
● RegDeletekey(): 删除一个关键字以及它的子关键字；
● RegDeleteValue(): 在指定的注册表关键字中删除一个带名字的值。
结束语
通过调用这些API以及VB提供给我们的函数，我们可以轻松实现注册表的任意关键字的读取、查询、建立和删除，详细的用法可查阅“API浏览器”，在这里就不再进行讨论了。 参考技术C 问注册表中的HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall，这个项下的就是当前系统中安装的所有软件，至于读取哪些项，你可以自己到注册表下看一下就知道。
注册表进放方法：点开始点运行，输入regedit.exe回车。

下面给出访问注册表的例程。希望对你有帮助。

Option Explicit

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(dest As Any, source As Any, ByVal numBytes As Long)

Private Declare Function ExpandEnvironmentStrings Lib "kernel32" Alias "ExpandEnvironmentStringsA" _
(ByVal lpSrc As String, ByVal lpDst As String, ByVal nSize As Long) As Long

''''//注册表 API 函数声明
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" _
(ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, _
ByVal samDesired As Long, phkResult As Long) As Long

Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long

Private Declare Function RegQueryValueEx Lib "advapi32.dll" Alias _
"RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, _
ByVal lpReserved As Long, lpType As Long, lpData As Any, _
lpcbData As Long) As Long

Private Declare Function RegSetValueEx Lib "advapi32" Alias "RegSetValueExA" _
(ByVal hKey As Long, ByVal lpValueName As String, _
ByVal Reserved As Long, ByVal dwType As Long, _
ByVal lpbData As Any, ByVal cbData As Long) As Long

Private Declare Function RegCreateKeyEx Lib "advapi32" Alias "RegCreateKeyExA" _
(ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, _
ByVal lpClass As String, ByVal dwOptions As Long, _
ByV......
参考技术D 哈哈 什么都会就是不会API？
你的意思是编写一个能够修改注册表的函数Reg（。。。）吧？追问

yes 你懂的

追答

把那么多操作集中在一起 有点复杂。。。你懂的

追问

复杂不是问题,做出来后再使用就方便了...你懂的

追答

我可帮你尝试着写前三个操作，多了代码的可读性和效率就很差。。。你懂的
留下你的邮箱。

追问

写在这就可以了 实在需要[e-mail]

追答

已发送 你看看。。。

本回答被提问者采纳

VB.NET的API调用

谁能告诉我下应该怎么调用吗?在下初学,不太明白想调用一个键盘的API
VB.NET(2003)键盘API调用(直接能用的代码,我不要理论)

现在我用我所知道的为楼主介绍VB.NET的API调用，请楼主浏览一下，看看行不行。
Windows API就是Windows系统的API函数简称（Application Program Interface，即：应用程序接口函数），它是Windows操作系统提供给各种开发基于Windows平台应用软件的开发语言的一些公用的函数，这些函数一般都比较底层，所以当各种开发语言使用自带的函数或类库已无法解决问题时，调用Windows API函数往往是一种非常直接、有效的解决方法。但由于在程序中调用Windows API函数一般都很复杂，所以对于程序员来说，是否能够灵活的使用Windows API函数，往往也是其水平高低的一个重要标志。但自从微软推出.Net框架以后，各种开发基于.Net平台下的程序语言，如Visual Basic .Net、Visual C＃等却很少使用Windows API函数，并且微软公司也不像以前那样，提倡在这些.Net开发语言中使用Windows API函数，其主要的原因如下：

1. .Net框架所附带的类库.Net FrameWork SDK是一个内容丰富、功能强大的软件开发包，各种Windows API函数所实现的各种功能几乎都可以在这个软件开发包中找到与之对应的部分。

2. 微软Visual Basic .Net、Visual C＃等目的是编写跨平台的应用程序，如果在Visual Basic .Net、Visual C＃等中使用Windows API函数，这也就注定了编写出的程序只能运行于Windows平台之下，而弱化了.NET的跨平台能力。这也就是为什么微软不提倡在.Net平台调用Windows API函数的原因。

虽然微软并不提倡在Visual Basic .Net、Visual C＃中调用Windows API函数，但由于目前.Net 框架推出时间较短，.Net FrameWork SDK中提供的类库还并不足以完全替换Windows API函数的所有功能，所以在某些时候，.Net开发语言还是必须要调用Windows API函数。

一.平台调用、托管DLL、非托管DLL简介：

托管DLL就是能够在公共语言运行库（Common Language Runtime，简称CLR）中能够直接引用的，并且扩展名为“DLL”的文件。具体所指就是封装各种命名空间所在的DLL文件，如System.dll等。非托管DLL就是平常所的动态链接库等，其中就包括了封装所有Windows API函数的DLL文件。各种非托管DLL中的函数在公共语言运行库中不能直接被调用，而需要经过.Net框架提供的“平台调用”服务后才可以。

“平台调用”是.Net框架为Visual Basic .Net、Visual C＃等.Net开发语言提供的一种服务，用以在托管代码中引入各种非托管DLL中封装的函数（其中包括Windows API函数）。“平台调用”依赖于元数据在运行时查找导出函数并封装其参数。图01公共语言运行库利用“平台服务”调用非托管DLL中的函数的流程图：

图01：“平台服务”的调用非托管函数的流程图

在托管代码中使用“平台调用”服务调用非托管DLL中封装的函数时，“平台服务”将依次执行以下操作：

1． 查找包含该函数所在的DLL文件。

2． 如果找到，则将该DLL文件 加载到内存中。

3． 查找函数在内存中的地址并将其参数推到堆栈上，并封送所需的数据。

4． 将控制权转移给非托管函数。 这样整个函数调用完成。

在Visual Basic .Net中使用“平台调用”服务，申明Windows API函数主要有二种具体的实现方法：

1． 使用DllImport特征类来申明Windows API函数。

2． 使用“Declare”语句来申明Windows API函数。

这二种方法虽有异曲同工之效，但在繁简上却有很大差异，第一种方法申明过程比较复杂，很容易在申明Windows API函数时出错，所以并不提倡。而第二种方法相对简单，并且又保存了以前Visual Basic中的很多语法，所以在平常时大都使用这种方法来申明Windows API函数。

二．VB.Net查看文件中图标的函数及申明Windows API的方法：

Visual Basic .Net要实现查看文件中的图标，目前只使用.Net FrameWork SDK是无法实现这种功能的，正如前面所说，主要是由于.Net FrameWork SDK推出的时间较短，其功能还不可能面面俱到。解决问题的关键是正确使用Windows API函数，其中所涉及到的Windows API函数主要有二个：其一是获得指定文件中的图标数目；其二是从指定文件的指定位置导出图标的Windows句柄。这二个函数都位于“Shell32.dll”文件中，并且函数的入口点都为“ExtractIcon”。下面是在Visual Basic .Net中分别使用DllImport特征类和“Declare”语句申明这二个Windows API函数的具体方法。

（1）.使用DllImport特征类来申明Windows API函数：

下面是在Visual Basic .Net中使用DllImport特征类申明二个Windows API函数的具体示例：

'函数ExtractIcon，其功能是是从指定文件的指定位置导出图标的Windows句柄。
＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" , EntryPoint := "ExtractIcon" ) ＞ _
Public Function _
ExtractIcon ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr
End Function
'函数Icon_Num，其功能是获得指定文件中的图标数目
＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" , EntryPoint := "ExtractIcon" ) ＞ _
Public Function _
Icon_Num ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As Integer ) As Integer
End Function

在使用DllImport特征类申明Windows API函数时，如果申明的函数名称和函数的入口点相同，则可以在申明Windows API函数时，省略定义函数入口点对应的代码，即EntryPoint对象字段对应的代码，这样声明ExtractIcon函数的代码也可以简化为如下所示：

＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" ) ＞ _
Public Function _
ExtractIcon ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr
End Function

（2）.使用“Declare”语句来申明Windows API函数：

使用“Declare”语句的确比使用DllImport特征类要简单了许多，下面是在Visual Basic .Net中使用“Declare”语句来声明上述二个Windows API函数的具体方法：

Declare Auto Function ExtractIcon Lib "Shell32.dll" Alias "ExtractIcon" ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr
'声明ExtractIcon函数
Declare Auto Function Icon_Num Lib "Shell32.dll" Alias "ExtractIcon" ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As Integer ) As Integer
'声明Icon_Num函数

在Visual Basic .Net中声明Windows API函数时，“Declare”语句中Alias关键字的作用相当于使用DllImport特征类中的EntryPoint对象字段。同样在使用“Declare”语句声明Windows API函数时，如果声明的函数和函数的入口点相同，也可以省略Alias关键字对应的代码，所以ExtractIcon函数也可以简化为如下：

Declare Auto Function ExtractIcon Lib "Shell32.dll" ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr

下面就结合一个示例的编写过程来掌握的这二个Windows API函数的具体使用方法，这个示例的作用就是读取指定文件中的图标数目，并显示文件中的图标。

三．本文中程序的编写、调试和运行环境：

（1）.视窗2000高级服务器版。

（2）.Visual Studio .Net 2003企业结构设计版，.Net FrameWork SDK版本号4322。

四．Visual Basic .Net读取文件中的图标的实现步骤：

下面介绍的示例，其功能读取指定文件中包含的图标数目，并把这些图标全部显示出来。下面是这个示例的实现步骤：

1. 启动Visual Studio .Net。

2. 选择菜单【文件】|【新建】|【项目】后，弹出【新建项目】对话框。

3. 将【项目类型】设置为【Visual Basic项目】。

4. 将【模板】设置为【Windows应用程序】。

5. 在【名称】文本框中输入【Visual Basic .Net查看文件中的图标】。

6. 在【位置】的文本框中输入【E:\VS.NET项目】，然后单击【确定】按钮，这样在【E:\VS.NET项目】目录中就产生了名称为【Visual Basic .Net查看文件中的图标】文件夹，里面存放着【Visual Basic .Net查看文件中的图标】项目的所有文件。具体如图02所示：

图02：【Visual Basic .Net查看文件中的图标】项目的【新建项目】对话框

7. 选择菜单【项目】|【添加新项】，在弹出的对话框中的【模板】设置为【模块】，【名称】文本框设置为【Module1.vb】后。单击【打开】按钮，则在项目中增加了一个模板文件，名称为【Module1.vb】。

8. 把Visual Stuido .Net的当前窗口切换到Module1.vb的代码编辑窗口，并在其Module1的代码区中添加下列代码，下列代码是用二种方式声明二个Windows API函数：

＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" ) ＞ _
Public Function _
ExtractIcon ( ByVal src As System.IntPtr , ByVal strFileName As String , ByVal uiIconIndex As UInt32 ) As System.IntPtr
End Function
'声明ExtractIcon函数
Declare Auto Function Icon_Num Lib "Shell32.dll" Alias "ExtractIcon" ( ByVal src As System.IntPtr , ByVal strFileName As String , ByVal uiIconIndex As Integer ) As Integer

9. 把Visual Studio .Net的当前窗口切换到Form1窗体的设计查看，并从【工具箱】中的【Windows窗体】选项卡中拖入下列组件到Form1窗体：

四个Label组件，其中二个用以显示提示信息，另外二个分别用以显示选择的文件名称和这个文件中包含的图标数目。

一个ListView组件，利用其显示大图标的属性用以显示选定文件中的图标。

一个OpenFileDialog组件，用以选择要查看图标的文件名称。

一个ImageList组件，它起的是桥梁的作用，首先把从文件中导出的图标存放到这里，然后再提供ListView组件显示出来。

一个Button组件。

10. 按照表01中数值来设定设定组件的主要属性：

组件类型 组件名称 属性 设置结果
Form Form1 Text VB.NET查看文件中的图标
Form1 MaximizeBox False
Form1 MinimizeBox False
Form1 FormBorderStyle FixedSingle
ListView ListView1 ImageList1 LargeImageList
ListView1 MultiSelect False
ListView1 Size Size ( 380 , 208 )
Button Button1 Text 选择文件
Button1 FlatStyle Flat
ImageList ImageList1 Size Size ( 32 , 32 )
ImageList1 TransparentColor Color.Transparent
Label Label1 Text 文件名称：
Label2 Text 图标数目：
Label3 Text ""
Label4 Text "0"
表01：【Visual Basic .Net查看文件中的图标】项目窗体中各组件的主要属性设定数值表

并按照图02中各组件的位置、大小和排列方式来调整窗体中各个组件：

图02：【Visual Basic .Net查看文件中的图标】项目的设计界面

11. 把Visual Studio .Net当前窗口切换到Form.vb的代码编辑窗口，并用下列代码替换Form1.vb中的Button1组件的Click事件的处理代码，下列代码是在Button1组件的Click事件中处理查看文件中图标的功能，具体如下：

Private Sub Button1_Click ( ByVal sender As System.Object , ByVal e As System.EventArgs ) Handles Button1.Click
If OpenFileDialog1.ShowDialog ( ) = DialogResult.OK Then
'清除组件中的所有项目
ListView1.Items.Clear ( )
ImageList1.Images.Clear ( )
Dim sfName As String = OpenFileDialog1.FileName
Label3.Text = sfName
Dim iIcon_Num As Integer = Icon_Num ( IntPtr.Zero , sfName , -1 )
'显示文件中的图标数目
Label4.Text = iIcon_Num.ToString ( )
Dim i As Integer
For i = 0 To iIcon_Num - 1 Step 1
'强制实现int到uint类型转换
Dim j As UInt32
j = System.Convert.ToUInt32 ( i )
Dim hIcon As System.IntPtr = ExtractIcon ( IntPtr.Zero , sfName , j )
'在imageList1组件中加入当然提取的图标
ImageList1.Images.Add ( Icon.FromHandle ( hIcon ).ToBitmap ( ) )
'在ListView组件中加入一个项目
ListView1.Items.Add ( "第" + ( i + 1 ).ToString ( ) + "个图标" )
'把加入项目的图象索引指向刚才加入图标在imagList1组件中的索引，从而显示图标
ListView1.Items ( i ).ImageIndex = i
Next i
End If
End Sub

12. 至此，在上述步骤都正确执行后，【Visual Basic .Net查看文件中的图标】项目的全部工作就完成了。单击快捷键F5就可以运行程序，此时单击【选择文件】按钮选择文件后，程序就能够读取这个文件中的图标及其数目，并显示出来了。具体如图03所示：

图03：【Visual Basic .Net查看文件中的图标】项目的运行界面

五．总结：

解决Visual Basic .Net查看文件中的图标的关键并非是使用.Net框架中提供的类库，而是使用Windows的API函数。虽然这与利用Visual Basic .Net开发跨平台程序的初衷相违背，但的确不失为一种解决问题的方法。有些时候通过Windows API函数能够快捷、方便的解决实际问题，而这往往是只使用.Net FrameWork SDK所望尘莫及的，但随着.Net FrameWork SDK内容的不断丰富，各种新的组成部分和新的功能不断加入，可以预见的是，在未来的.Net FrameWork SDK中必将拥有可以替换本文中介绍的二个Windows API函数的组成部分。 参考技术A （1）.使用DllImport特征类来申明Windows API函数：
下面是在Visual Basic .Net中使用DllImport特征类申明二个Windows API函数的具体示例：
'函数ExtractIcon，其功能是是从指定文件的指定位置导出图标的Windows句柄。
＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" , EntryPoint := "ExtractIcon" ) ＞ _
Public Function _
ExtractIcon ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr
End Function
'函数Icon_Num，其功能是获得指定文件中的图标数目
＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" , EntryPoint := "ExtractIcon" ) ＞ _
Public Function _
Icon_Num ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As Integer ) As Integer
End Function
在使用DllImport特征类申明Windows API函数时，如果申明的函数名称和函数的入口点相同，则可以在申明Windows API函数时，省略定义函数入口点对应的代码，即EntryPoint对象字段对应的代码，这样声明ExtractIcon函数的代码也可以简化为如下所示：
＜ System.Runtime.InteropServices.DllImport ( "Shell32.dll" ) ＞ _
Public Function _
ExtractIcon ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr
End Function

（2）.使用“Declare”语句来申明Windows API函数：
使用“Declare”语句的确比使用DllImport特征类要简单了许多，下面是在Visual Basic .Net中使用“Declare”语句来声明上述二个Windows API函数的具体方法：
Declare Auto Function ExtractIcon Lib "Shell32.dll" Alias "ExtractIcon" ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr
'声明ExtractIcon函数
Declare Auto Function Icon_Num Lib "Shell32.dll" Alias "ExtractIcon" ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As Integer ) As Integer
'声明Icon_Num函数
在Visual Basic .Net中声明Windows API函数时，“Declare”语句中Alias关键字的作用相当于使用DllImport特征类中的EntryPoint对象字段。同样在使用“Declare”语句声明Windows API函数时，如果声明的函数和函数的入口点相同，也可以省略Alias关键字对应的代码，所以ExtractIcon函数也可以简化为如下：
Declare Auto Function ExtractIcon Lib "Shell32.dll" ( ByVal src As System.IntPtr , ByVal strFileName As string , ByVal uiIconIndex As UInt32 ) As System.IntPtr 参考技术B Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)'声明键盘API函数

'引用的话把下面的代码加入你要引用的地方

Call keybd_event(0, 0, 0, 0)'第一个参数是你要模拟按下的键的ASCII码,第二个参数我也没研究懂(好象说是扫描码,试过,可是有问题就不知道了,第三个,貌似是指键盘的弹起按下,最后一个,也不知道.)本回答被提问者和网友采纳 参考技术C 可以调用啊.你要调什么API函数呢?