汇编：实验12：自定义零号中断处理程序

Posted 2022-12-12 小杰666

题目

自定义0号中断处理程序，使得除法溢出发生时，调用自定义的0号中断处理程序。

然后在屏幕中间显示红色字：“divide error!”

代码

; 自定义0号中断处理程序
assume cs:code
code segment
start:
    mov ax,cs
    mov ds,ax
    mov si,offset do0       ; ds:si指向中断程序代码的开始地址
    mov ax,0
    mov es,ax
    mov di,200h              ; es:di指向中断程序存放处开始地址
    mov cx,offset do0end - offset do0   ; 计算中断程序长度
    cld                             ; 设置串传送方向为正
    rep movsb                 ; 串传送，把中断程序代码复制到0:200h处

    ; 设置中断向量
    mov ax,0
    mov es,ax
    mov word ptr es:[0*4],200h
    mov word ptr es:[0*4+2],0

    mov ax,4c00h
    int 21h

do0: 
    jmp short do0start     ; jmp指令长2字节
    db "divide error!"      ; 显示内容放在中断程序自身内部

do0start:
    mov ax,cs                ; 中断程序装载到0:200h后，被调用时，cs=0,ip=200
    mov ds,ax
    mov si,202h            ; ds:si指向中断程序中的字符串的开头

    mov ax,0b800h
    mov es,ax
    mov di,12*160+36*2     ; es:di指向显存空间中间，即屏幕中间位置

    mov ah,00000100b       ; 设为红色字
    mov cx,13                      ; 字符串长度13
s:
    mov al,[si]
    mov es:[di],ax
    inc si
    add di,2
    loop s

    mov ax,4c00h           ; 中断程序中包含退出，执行中断程序后返回到系统
    int 21h

do0end:
    nop                    ; 填充一个空字节，为了让do0end参与计算中断程序长度

code ends
end start

执行结果

截图：