汇编：实验15：安装新的int9中断例程

Posted 2021-06-27 小杰666

题目

安装一个新的int 9中断例程，功能是在DOS下，按下A键后，除非不松开，否则一松开就显示满屏幕的A。

这个程序在win2k的DOS下会有问题，dosbox中执行正常。

源码

汇编源码：

; 实验15
; 安装新的int9中断例程
; 功能是在DOS下，按下A键，除非一直按住，只要松开就显示满屏幕的A
; 此程序在DOS下有问题，在dosbox下执行正常

assume cs:code

stack segment
    db 128 dup (0)
stack ends

code segment
start:
    cli
    mov ax,stack
    mov ss,ax
    mov sp,128
    sti

    push cs
    pop ds 

    mov ax,0
    mov es,ax

    mov si,offset int9 ; ds:si指向新int9中断例程的代码
    mov di,204h        ; es:di指向新int9例程存放处
    mov cx,offset int9end - offset int9
    cld
    rep movsb

    ; 原int9入口地址保存在0:200h、0:202h
    push es:[9*4]
    pop es:[200h]
    push es:[9*4+2]
    pop es:[202h]

    ; 中断向量表9号中断保存新入口地址
    cli
    mov word ptr es:[9*4],204h
    mov word ptr es:[9*4+2],0
    sti

    mov ax,4c00h
    int 21h

; 新int9中断例程
int9:
    push ax
    push bx
    push cx
    push es 

    in al,60h

    pushf
    call dword ptr cs:[200h] ; 此中断执行时，cs=0

    cmp al,1eh+80h ; A按键的通码1eh，断码=通码+80h
    jne int9ret

    mov ax,0b800h
    mov es,ax
    mov bx,0
    mov cx,2000
s:
    mov byte ptr es:[bx],'A'
    add bx,2
    loop s

int9ret:
    pop es
    pop cx
    pop bx
    pop ax
    iret

int9end:
    nop

code ends
end start

结果

执行结果：