oracle EXECUTE IMMEDIATE动态执行sql及异常信息打印

Posted 2023-02-21 zz_cl

oracle内置的EXECUTE IMMEDIATE可以用来解析并执行动态sql语句，动态拼写的sql中可以使用USING 参数1，参数2....来绑定变量。当拼写比较复杂的sql时，可能会出现一些脚本语法的错误，可以用oracle内置的SQLCODE、SQLERRM来打印相关的异常信息。

沿用上一篇oracle存储过程调用小技巧的测试表tt_est，新建一个存储过程p_tst。

CREATE OR REPLACE PROCEDURE p_tst(
    p_name IN VARCHAR2,
    p_return in out VARCHAR2)
AS
  v_error_code         VARCHAR2(10);                           --错误码
  v_description        VARCHAR2(160);                          --错误信息
  v_cnt                INTEGER := 0;                           --影响行数
  v_table_name         VARCHAR2(30);                            --表名
  v_sql                VARCHAR2(5000);                         --动态脚本
BEGIN
  --空值返回
  IF trim(p_name) IS NULL THEN
    RETURN;
  END IF;
  v_table_name     := 'tt_est';
  v_sql := 'update ' || v_table_name || ' set name = ''执行了update'' where name = :p_name';
  dbms_output.put_line (v_sql);
  EXECUTE IMMEDIATE v_sql USING p_name;
  v_cnt := SQL%rowcount;
  COMMIT;
  dbms_output.put_line ('成功update了' || v_cnt || '行');
  -- 返回成功
  p_return := 'run success'; 
exception
WHEN others THEN
  v_error_code   := SQLCODE;
  v_description   := substr(sqlerrm, 1, 160);
  ROLLBACK;
  dbms_output.put_line ('update失败，错误码：' || v_error_code || '; 错误信息：' || v_description);
  -- 返回失败
  p_return := 'run fail';
END p_tst;

存储过程调用脚本

declare 
returnstr varchar2(20);
begin
p_tst('aa',returnstr);
dbms_output.put_line(returnstr);
end;

通过定义一个变量returnstr，作为存储过程p_tst中in out参数的传递值，来输出存储过程调用成功与失败的信息。

可以发现，数据成功更新了。

尝试一下sql执行失败是的异常信息分析，可以对sql做一下小改动，将表名改一下，执行后再调用存储过程，就生成对应的异常信息了