汇编语言实现在80*25彩色字符模式下显示字符串

Posted 2022-12-10 杨龙飞的博客

记得大一刚接触c语言的时候,用c语言打印出了彩色的字符串,但感觉很神奇,转眼间,已经成为大三狗了,哈哈^^. 好了,不说废话了,今天,就来看看怎样用汇编语言打印彩色的字符串.

80*25彩色字符模式

在内存地址空间中,B8000H~BFFFFH共32KB的空间,为80*25彩色字符模式的显示缓冲区,向这个地址空间写数据,写入的内容将立即出现在显示器上.
在80*25彩色字符模式下,显示器可以显示25行,每行80个字符,每个字符可以有256种属性(背景色,闪烁,高亮等组合信息). 
这样一个字符在显示缓冲区中就要占两个字节,分别存放字符的ASCII码和属性，80*25模式下,一屛内容在显示缓冲区中占4000个字节.
显示缓冲区分为8页,每页4KB，显示器可以任意显示任意一页的内容，一般情况下,显示第0页的内容,也就是B8000~B8F9FH中的4000个字节.  
然后大家可以想想第一页的第一行是地址是从B8000H~???(ps:答案在最后给出)

tip:一行80个字符,一个字符占2个字节. 偶地址存放字符。
在显示缓冲区中,偶地址存放字符串,及地址存放字符的颜色属性.
举个例子:
场景:用汇编把”ABCD”以彩色的形式打印出来。(假设以80*25显示缓冲区的第一页开始存,)A的ASCII在B8000H(偶地址),颜色属性在B800001(奇地址) .
一个在屏幕上显示的字符,具有前景色(字符颜色),背景色，高亮度和闪烁的方式显示,前景色、背景色、闪烁、高亮等信息被记录在颜色属性的每一位中,
颜色属性字节格式:
7 6 5 4 3 2 1 0
含义: BL R G B I R G B
闪 　 背景 前景
烁
把”welocome to masm!”;用三种不同的颜色显示在屏幕上.
代码如下:

assume cs:code,ds:data,ss:stack
data segment 
    db 'welcome to masm!' ;定义要显示的字符串(共16个字节)
    db 02h,24h,71h  ;定义了三种颜色
data ends
stack segment 
    dw 8 dup(0)   ;定义栈段,保存相关寄存器的值
stack ends
code segment
start:
    mov ax,data　
    mov ds,ax  ;ds中存放data段的段地址　
    mov ax,stack 
    mov ss,ax   ;ss中存放stack段的段地址
    mov sp,10h　;把sp指针指向栈顶的下一个地址.
    mov bx,0    ;存偏移地址,用来取每个字符
    mov di,0   ; 
    mov ax,0b872h;算出屏幕12行中间的显存的段起始位置放入ax
    mov cx,3; 外循环为3次,因为要显示三个ｗ字符串
s3: push cx 
    push ax
    push di ;三个进栈操作作为外循环s3保存相关寄存器的值,以防它们的值在内循环中被破坏
    mov es,ax 
    mov si,0
    mov di,0
    mov cx,10h 
    s1: mov al,ds:[bx+si]
        mov es:[bx+di],al
        inc si ;读下一个字符
        add di,2 ;每存一个字符,空一个字节,在下一个循环中存放颜色属性值. 
    loop s1;此循环实现在偶地址中存放字符串
        mov si,1 ;将si置为1，为在奇地址中存放字符的颜色.
        pop di ;将di的值恢复成进入内循环之前的时候的值
        mov al,ds:10h[bx+di] ;取颜色属性
        mov cx,10h ;第二个内循环也为10h次
    s2: mov es:[bx+si],al
        add si,2
    loop s2 ;此循环实现奇地址存放字符的颜色属性. 

        inc di ;取第二种颜色
        pop ax　
        add ax,0ah ; 将显存的段起始地址设为当前行的下一行
        pop cx
    loop s3
        mov ax,4c00h
        int 21h

code ends 
end start

执行结果: