代码重定位

Posted 2022-03-16 正在起飞的蜗牛

1、程序段介绍

参见博客：《C语言程序段的定义、实际应用分析》；

2、什么是代码重定位

代码重定位就是将代码搬运到链接地址处，实际在操作时就是将代码复制一份到链接地址处。我们把代码下载到设备的Flash中，然后代码运行却要求另一个地址，于是我们就赋值一份代码到指定的地址处进行运行。

3、代码重定位相关概念

3.1、位置有关码和位置无关码

简单来将就是代码和代码运行时的地址有关联。位置无关码对运行时的地址没有要求，放在哪里都可以；位置有关码在运行时则必须在指定的地址处。位置有关码都是相对跳转，都是相对于PC的偏移量，所以在哪个地址都可以运行。位置有关码是绝对地址，必须在相应的地址才能运行。

3.2、链接地址

见博客：《嵌入式开发中的链接地址、运行地址、加载地址、存储地址、实际运行地址的区别》;

3.3、Nand Flash和Nor Flash

(1)Nand Flash:单位容量价格低、CPU不能直接访问、容易坏块；
(2)Nor Flash：单位容量价格高、CPU能直接访问、不易坏块、但是不能像内存一样写；
总结：代码必须保存在Flash、硬盘等掉电不丢失的存储介质中，但是代码又不能再这些ROM存储介质中直接运行，必须在RAM中运行，所以设备启动时必须要先将代码重定位到RAM中。

4、代码重定位思路

(1)先用一段位置无关码进行代码重定位，将代码复制一份到链接地址处；
(2)重定位完成后，长跳转到链接地址处那份代码接着执行剩下的代码；

5、链接脚本：

SECTIONS

	. = 0xd0024000;
	
	.text : 
		start.o
		* (.text)
	
    		
	.data : 
		* (.data)
	
	
	bss_start = .; 
	.bss : 
		* (.bss)
	
	
	bss_end  = .;	

6、代码重定位汇编代码

/*
 * 文件名：	led.s	
 * 作者：	朱老师
 * 描述：	演示重定位（在SRAM内部重定位）
 */

#define WTCON		0xE2700000

#define SVC_STACK	0xd0037d80
.global _start					// 把_start链接属性改为外部，这样其他文件就可以看见_start了
_start:
	// 第1步：关看门狗（向WTCON的bit5写入0即可）
	ldr r0, =WTCON
	ldr r1, =0x0
	str r1, [r0]
	
	// 第2步：设置SVC栈
	ldr sp, =SVC_STACK
	
	// 第3步：开/关icache
	mrc p15,0,r0,c1,c0,0;			// 读出cp15的c1到r0中
	//bic r0, r0, #(1<<12)			// bit12 置0  关icache
	orr r0, r0, #(1<<12)			// bit12 置1  开icache
	mcr p15,0,r0,c1,c0,0;
	
	// 第4步：重定位
	// adr指令用于加载_start当前下载地址
	adr r0, _start  		// adr加载时就叫短加载		
	// ldr指令用于加载_start的链接地址:0xd0024000
	ldr r1, =_start // ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载	
	// bss段的起始地址
	ldr r2, =bss_start	// 就是我们重定位代码的结束地址，重定位只需重定位代码段和数据段即可
	cmp r0, r1			// 比较_start的运行时地址和链接地址是否相等
	beq clean_bss		// 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss
						// 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位
						// 重定位完成后继续执行clean_bss。

// 用汇编来实现的一个while循环
copy_loop:
	ldr r3, [r0], #4    // 源
	str r3, [r1], #4	// 目的   这两句代码就完成了4个字节内容的拷贝
	cmp r1, r2			// r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4总能等于r2
	bne copy_loop

	// 清bss段，其实就是在链接地址处把bss段全部清零
clean_bss:
	ldr r0, =bss_start					
	ldr r1, =bss_end
	cmp r0, r1				// 如果r0等于r1，说明bss段为空，直接下去
	beq run_on_dram			// 清除bss完之后的地址
	mov r2, #0
clear_loop:
	str r2, [r0], #4		// 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），
	cmp r0, r1				// 然后r0 = r0 + 4
	bne clear_loop

run_on_dram:	
	// 长跳转到led_blink开始第二阶段
	ldr pc, =led_blink				// ldr指令实现长跳转,
	
	// 从这里之后就可以开始调用C程序了
	//bl led_blink					// bl指令实现短跳转
	
// 汇编最后的这个死循环不能丢
	b .
	

7、代码解析：

(1)首先判断下载地址和链接地址是否相等，如果不相等就要重定位；
(2)用循环的方式，每次4字节将代码段、数据段重定位到链接地址；
(3)将bss段进行清零，这就是为什么C语言中未初始化的全局变量默认值是零的原因；
(4)长跳转到函数执行；

8、长跳转和短跳转

(1)定义：长跳转的跳转范围比较大；短跳转的跳转范围比较小；
(2)代码重定位中的作用：重定位完成后，设备里就有两份一模一样的代码，一份在下载地址处，一份在链接地址处。如果用短跳转指令(bl)则是调用的下载地址处的代码，如果是长跳转(ldr pc)则是调用下载地址处的代码。在完成重定位后一般都是用长跳转到链接地址处的代码，要不然就没必要重定位了。