Godot一个节点发射器（泼水机）

Posted 2022-03-11 张学徒

Godot 3.4.2

向一个方向随机发射一个子弹，如果连续发射多次，看起来像泼水机一样 😂

上图发射的子弹是一个 RigidBody 类型的节点

#============================================================
#	Launch Bullet
#============================================================
#  发射节点
# * 调用 control 方法进行使用
#============================================================
# @datetime: 2022-3-1 21:31:31
#============================================================
class_name LaunchBullet
extends Node2D


signal launched(bullet_node)


export var bullet_ : PackedScene setget set_bullet
## 角度偏移
export (float, -360, 360, 0.1) var angle_offset : float = 0
export (float, -360, 360, 0.1)  var angle_offset_max : float = 0
## 间隔发射时间
export var interval : float = 1.0
## 爆炸时间
export var explode_time : float = 1.0
## 节点移动速度
export var speed : int = 300
## 速度波动范围
export var speed_fluctuation : int = 0

var __curr_dir__ = Vector2(0,0)
var __root__ : Node
var __interval_timer__ := Timer.new()


#============================================================
#   Set/Get
#============================================================
func get_interval() -> float:
	return interval

func get_explode_time() -> float:
	return explode_time

func set_bullet(value: PackedScene) -> void:
	bullet_ = value



#============================================================
#   内置
#============================================================
func _ready():
	__interval_timer__.one_shot = true
	__interval_timer__.autostart = false
	__interval_timer__.connect("timeout", self, "refresh")
	add_child(__interval_timer__)
	
	__root__ = get_tree().root


#============================================================
#   自定义
#============================================================
## 控制使用
func control(data = null):
	if (__interval_timer__.time_left <= 0 
		and bullet_
	):
		var b = bullet_.instance() as Bullet
		if explode_time > 0:
			var timer = Timer.new()
			timer.wait_time = explode_time
			timer.autostart = true
			timer.one_shot = true
			# 连接到子弹的 explode 爆炸方法上
			# 如果没有这个方法，改为 queue_free 即可
			if timer.connect("timeout", b, "explode") != OK:
				printerr("连接 explode 信号失败！")
			b.add_child(timer)
		created(b)
		__root__.add_child(b)
		# 开始倒计时
		__interval_timer__.start(interval)
		emit_signal("launched", b)


##  创建的节点
## @bullet  
func created(bullet) -> void:
	bullet.global_position = self.global_position
	# 偏移角度
	var angle = deg2rad(rand_range(angle_offset, angle_offset_max))
	bullet.global_rotation = global_rotation + angle
	# 施加的力
	var velocity = Vector2.UP.rotated(
			global_rotation + angle
		) * (speed + rand_range(-speed_fluctuation, speed_fluctuation))
	# 如果节点是 RigidBody2D 类型节点
	# 则直接 bullet.linear_velocity = velocity 即可


## 刷新
func refresh():
	__interval_timer__.stop()