如何将TXT文档里的文字改编码成utf－8

Posted 2023-05-06

我在手机里将编码改成utf－8就能查看了

把下面代码保存为“转换.vbs”，运行它就可以批量转换TXT文件的编码了。
on error resume next
Set WshShell=WScript.CreateObject("Shell.Application")
dirPath=WshShell.BrowseForFolder(0, "请选择路径", 0, "").items().item().path
if right(dirPath,1)<>"\" then dirPath=dirpath&"\"
ma=inputbox("请输入要转换为的编码","","UTF-8")
if ma="" or dirPath="\" or msgbox("在使用前请确认已备份文件夹"&dirPath,1)=2 then WScript.Quit

'遍历文件夹下的文件
Set FSO = CreateObject("scripting.filesystemobject")
Set f = FSO.GetFolder(dirPath)
Set fs = f.files
For Each fileN in fs
FN=dirPath&fileN.name&""
if ".txt"=lcase(right(FN,4)) then Call WriteToFile(FN, ReadFile(FN, CheckCode(FN)), ma)
Next
Set FSO = Nothing
wscript.echo "全部成功"

'检测文件的编码
Function CheckCode (FileUrl)
Dim slz
set slz = CreateObject("Adodb.Stream")
slz.Type = 1
slz.Mode = 3
slz.Open
slz.Position = 0
slz.Loadfromfile FileUrl
Bin=slz.read(2)
if AscB(MidB(Bin,1,1))=&HEF and AscB(MidB(Bin,2,1))=&HBB Then
Codes="UTF-8"
elseif AscB(MidB(Bin,1,1))=&HFF and AscB(MidB(Bin,2,1))=&HFE Then
Codes="Unicode"
else
Codes="GB2312"
end if
slz.Close
set slz = Nothing
CheckCode=Codes
End Function

'以指定的编码读取文件
Function ReadFile(FileUrl, CharSet)
On Error Resume Next
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
wscript.echo Str
ReadFile = Str
End Function

'以指定的编码写文件
Function WriteToFile (FileUrl, Str, CharSet)
On Error Resume Next
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End Function追问

选择目录后会出现一个 windows script host 的工作条 一直在那关了就显示全部成功 但是仍然没有效果

追答

我本机测试过没问题，这里用到了三个组件，估计是你的电脑不全支持吧。你原来的编码是什么？

追问

不知道啊 打开是一堆乱码

追答

用记事本打开，文件——另存为，在最下面可以看到原来的编码。

追问

是ANSI的 你说的3个组件是什么我安一下

追答

我发个小工具给你吧，更省事。

参考技术A 用记事本打开，选择“另存为。。”，编码那里选 UTF-8，就可以了啊追问

这么简单就解决了 我会再提问吗

追答

当然可以，没有调查就没有发言权，我肯定是试过的了。查看过二进制码了也。用记事本是最简单的，也可以用 UltraEdit 转码。
那么请问，你这样子转换出来的不是 utf-8，那么是什么码呢？

追问

是 utf-8 但是还是乱码看不了

如何将txt文字编码换成unicode

将你所要转成UNICODE的文字放到TXT文档里.另存为,在编码那栏选择unicode就可以了!! 参考技术A 楼上正解，用UEDIT也可，功能更强一点。