向多个接收者发送电子邮件程序
Posted
技术标签:
【中文标题】向多个接收者发送电子邮件程序【英文标题】：Send Email procedure to multiple receivers 【发布时间】：2021-12-28 02:24:02 【问题描述】：请问我的程序有什么问题吗？我尝试运行该程序，它仅适用于“CC”列表接收者，但“TO”列表接收者无法接收电子邮件。任何可以帮助我的机构将不胜感激！请提供修改后的代码。
create or replace PROCEDURE check_ap_reject_list (errbuf VARCHAR2, retcode NUMBER) IS
CURSOR c1 IS
SELECT distinct b.NAME AP_ORG, a.ORG_ID ORG_ID, a.source source,
a.INVOICE_ID INVOICE_ID,reject_lookup_code Reject_Reason,
a.INVOICE_NUM Invoice_Num, a.INVOICE_DATE Invoice_Date, a.GL_DATE GL_Date,
a.VENDOR_NAME Vendor_Name, a.VENDOR_SITE_CODE Vendor_Site_Code,
a.INVOICE_AMOUNT INVOICE_AMOUNT, a.INVOICE_CURRENCY_CODE INVOICE_CURRENCY_CODE, a.EXCHANGE_RATE EXCHANGE_RATE
FROM apps.ap_interface_rejections,
apps.ap_invoices_interface a,
apps.hr_all_organization_units b,
apps.ap_invoice_lines_interface d
WHERE (((parent_id = a.invoice_id AND parent_table = 'AP_INVOICES_INTERFACE') OR (parent_id = d.invoice_line_id AND parent_table = 'AP_INVOICE_LINES_INTERFACE')))
AND a.INVOICE_ID = d.INVOICE_ID
AND a.ORG_ID = b.ORGANIZATION_ID
AND a.source = 'RMS'
;
r1 c1%rowtype;
c utl_smtp.connection;
v_instance varchar2(9);
x_email_to varchar2(4000);
x_email_cc varchar2(4000);
v_temp_str varchar2(4000);
v_temp number;
v_r1_row_num number;
v_check number;
PROCEDURE send_data(p_data in varchar2) as
BEGIN
utl_smtp.write_raw_data(c, utl_raw.cast_to_raw(p_data || utl_tcp.crlf));
--fnd_file.put_line(fnd_file.output, p_data);
END;
BEGIN
SELECT count(distinct a.INVOICE_NUM)
into v_check
FROM apps.ap_interface_rejections, apps.ap_invoices_interface a, apps.hr_all_organization_units b, apps.ap_invoice_lines_interface d
WHERE (((parent_id = a.invoice_id AND parent_table = 'AP_INVOICES_INTERFACE') OR (parent_id = d.invoice_line_id AND parent_table = 'AP_INVOICE_LINES_INTERFACE')))
AND a.INVOICE_ID = d.INVOICE_ID
AND a.ORG_ID = b.ORGANIZATION_ID
AND a.source = 'RMS';
IF v_check > 0 THEN
select name into v_instance from V$DATABASE;
x_email_to := 'danielliu@abc.com, vincentyuan@abc.com, christinewong@abc.com';
x_email_cc := 'andycheng@abc.com, tonyfok@abc.com';
c := utl_smtp.open_connection('LCEX7',25);
--utl_smtp.open_connection('smtp.office365.com',587);
--utl_smtp.helo(c, 'LCEX7');
utl_smtp.helo(c, 'LCEX7');
utl_smtp.mail(c, 'lc_ofin@abc.com');
-- utl_smtp.rcpt( c, x_email_to);
-- utl_smtp.rcpt( c, x_email_cc);
v_temp_str := replace(x_email_to, ',', ';');
v_temp_str := replace(x_email_cc, ',', ';');
while length(v_temp_str) > 0 loop
v_temp := instr(v_temp_str, ';', 1, 1);
if v_temp > 0 then
utl_smtp.rcpt(c, trim(substr(v_temp_str, 1, v_temp - 1)));
v_temp_str := substr(v_temp_str, v_temp + 1, length(v_temp_str));
else
utl_smtp.rcpt(c, trim(v_temp_str));
v_temp_str := null;
end if;
end loop;
utl_smtp.open_data(c);
utl_smtp.write_data(c,'From: "Oracle Fin (' || v_instance ||') " <lc_ofin@abc.com>' || utl_tcp.CRLF);
utl_smtp.write_data(c, 'To: ' || x_email_to || utl_tcp.CRLF);
utl_smtp.write_data(c, 'Cc: ' || x_email_cc || utl_tcp.CRLF);
utl_smtp.write_data(c, 'Subject: AP invoice reject list ' || to_char(sysdate,'MM/dd/yyyy HH:mm:ss') || utl_tcp.CRLF);
utl_smtp.write_data(c, 'MIME-Version:' || '1.0' || utl_tcp.CRLF);
utl_smtp.write_data(c,'Content-Type: ' || 'text/html; charset=utf-8' ||utl_tcp.CRLF);
utl_smtp.write_data(c, 'Content-Transfer-Encoding: ' || '"8Bit"' || utl_tcp.CRLF);
send_data('<html><body>');
send_data('<p>Dear All,</p>');
send_data('<p>Please find the enclosed AP reject list and advise. Thanks!</p>');
send_data('<table border=''0'' width=''100%'' cellpadding=''1'' cellspacing=''1''>');
send_data('<tr style=''font-size:75%;font-weight:bold;''>');
send_data('<td>AP ORG</td>
<td>ORG ID</td>
<td>Source</td>
<td>INVOICE ID</td>
<td>Reject Reason</td>
<td>Invoice Num</td>
<td>Invoice Date</td>
<td>GL Date</td>
<td>Vendor Name</td>
<td>Vendor Site Code</td>
<td>INVOICE AMOUNT</td>
<td>INVOICE CURRENCY CODE</td>
<td>EXCHANGE RATE</td>');
v_r1_row_num := 0;
open c1;
loop
fetch c1
into r1;
exit when c1%notfound;
if (mod(v_r1_row_num,2)=0) then
send_data('<tr style=''font-size:75%;background-color:#E0EBFF;''>');
else
send_data('<tr style=''font-size:75%;''>');
end if;
send_data('<td>' || r1.AP_ORG || '</td>
<td>' || r1.ORG_ID || '</td>
<td>' || r1.source || '</td>
<td>' || r1.INVOICE_ID || '</td>
<td>' || r1.Reject_Reason || '</td>
<td>' || r1.Invoice_Num || '</td>
<td>' || r1.Invoice_Date || '</td>
<td>' || r1.GL_Date || '</td>
<td>' || r1.Vendor_Name || '</td>
<td>' || r1.Vendor_Site_Code|| '</td>
<td>' || r1.INVOICE_AMOUNT || '</td>
<td>' || r1.INVOICE_CURRENCY_CODE || '</td>
<td>' || r1.EXCHANGE_RATE || '</td></tr>');
v_r1_row_num := v_r1_row_num + 1;
END LOOP;
CLOSE c1;
send_data('</table>');
send_data('<p>Best Regards,</p>');
send_data('<p>Technology Department</p>');
send_data('</body></html>');
utl_smtp.close_data(c);
utl_smtp.quit(c);
end if ;
END check_ap_reject_list;
【问题讨论】：
【参考方案1】：您需要为每个电子邮件收件人（无论是抄送还是收件人）提供一个 RCPT，然后在电子邮件数据中的适当位置使用“收件人”和“抄送”一行。所以一些伪代码将类似于：
declare
x_email_to sys.odcivarchar2list := sys.odcivarchar2list('danielliu@abc.com, vincentyuan@abc.com, christinewong@abc.com');
x_email_cc sys.odcivarchar2list := sys.odcivarchar2list('andycheng@abc.com, tonyfok@abc.com');
begin
...
... normal email initialisation (open,helo,etc)
...
for i in 1 .. x_email_to.count loop
utl_smtp.rcpt(l_conn, x_email_to(i));
end loop;
for i in 1 .. x_email_cc.count loop
utl_smtp.rcpt(l_conn, x_email_cc(i));
end loop;
for i in 1 .. x_email_to.count loop
utl_smtp.write_data(c, 'To: ' || x_email_to(i) || utl_tcp.CRLF);
end loop;
for i in 1 .. x_email_cc.count loop
utl_smtp.write_data(c, 'Cc: ' || x_email_cc(i) || utl_tcp.CRLF);
end loop;
...
... rest of email
...
end;
我正在使用一个数组，以便轻松遍历每个电子邮件地址。在您的情况下，您可以只解析字符串以查找每个评论，但概念是相同的。
每位收件人一份 RCPT 每个 CC 和 TO 一个 write_data【讨论】：
【参考方案2】：如果您必须使用 utl_smtp 包，Connor 的回答是正确的。
但是，除非您需要直接针对 SMTP 协议进行操作，否则这是一种相对繁琐的电子邮件发送方式。在旧版本的 Oracle 中，这就是您发送电子邮件的方式。早在 10g 时代，Oracle 就有 utl_mail.send procedure，它可以让您将逗号分隔的收件人列表传递给 to、cc 和 bcc 列表以及 HTML 消息
utl_mail.send( sender => 'reply-to@your-domain.com',
recipients => x_email_to,
cc => x_email_cc,
subject => 'Subject: AP invoice reject list ' ||
to_char(sysdate,'MM/dd/yyyy HH:mm:ss'),
message => x_html_document,
mime_type => 'text/html' );
无需担心手动添加所有 CRLF，无需对write_data 和/或write_raw_data 进行数十次调用。只需在本地变量中构建要发送的 HTML 文档并发送即可。 Oracle 已经为 99% 的用例构建了基础架构。
如果您碰巧在您的数据库中安装了 APEX（即使您没有 APEX 应用程序），您也可以使用 apex_mail package，它有一个类似的 send 包。如果您想发送同一电子邮件的 HTML 和纯文本版本，该版本可以简化流程，以便电子邮件客户端不支持 HTML 的用户可以查看它。并且由于apex_mail 将要发送的消息排入队列而不是直接与 SMTP 服务器对话，apex_mail 调用是事务性的，因此如果父事务失败，它们将回滚，如果这是一个过程，这很好避免向内部用户发送垃圾邮件发生意外错误时可以重试。
【讨论】：
强烈建议大家将 APEX 安装到他们的数据库中，即使他们从未使用过 APEX GUI。你会得到很多很棒的实用程序以上是关于向多个接收者发送电子邮件程序的主要内容，如果未能解决你的问题，请参考以下文章
AlertManager - 根据特定 Jobnames 的路由向不同的接收者发送警报
Python smtplib 向对应行中的收件人发送电子邮件