如何使用依赖于包装它的较短列表的 map 循环较长的列表以将某些函数应用于 Common Lisp 中的较长列表？

Posted 2023-03-15

【中文标题】如何使用依赖于包装它的较短列表的 map 循环较长的列表以将某些函数应用于 Common Lisp 中的较长列表？

【英文标题】：How do I loop over a longer list with map that depends on a shorter list wrapping it to apply some function to the longer list in Common Lisp?

【发布时间】：2021-04-03 07:42:14

【问题描述】：

基本上，我希望在 Common Lisp 中使用与此代码等效的代码，但最好以更方便的方式。

(defun circular (items) 
  (setf (cdr (last items)) items))

(map 'list #'(lambda (x y) (+ x y)) 
     (circular '(1 2 3)) '(2 3 4 5))
;; ==> (3 5 7 6)

【参考方案1】：

如果你使用 SERIES 包，你可以使用 SERIES 函数：

创建一个无限系列，不断重复给定项目 给定的顺序。

如果项目是静态已知的，即，这有效。不是来自运行时给出的值列表。

在下面，代码扫描一个列表，同时迭代无限系列 1 2 3 ...。两个系列都与 mapping 并行迭代，如 s 和 n，映射生成一系列(cons s n)。结果被收集为一个列表：

(collect 'list
  (mapping ((s (scan 'list '(a b c d e f g h)))
            (n (series 1 2 3)))
    (cons s n)))

结果是：

((A . 1) (B . 2) (C . 3) (D . 1) (E . 2) (F . 3) (G . 1) (H . 2))

系列进行流融合，扩展代码为：

(let* ((#:out-823 (list 1 2 3)))
  (let (#:elements-816
        (#:listptr-817 '(a b c d e f g h))
        #:items-821
        (#:lst-822 (copy-list #:out-823))
        #:items-826
        (#:lastcons-813 (list nil))
        #:lst-814)
    (declare (type list #:listptr-817)
             (type list #:lst-822)
             (type cons #:lastcons-813)
             (type list #:lst-814))
    (setq #:lst-822 (nconc #:lst-822 #:lst-822))
    (setq #:lst-814 #:lastcons-813)
    (tagbody
     #:ll-827
      (if (endp #:listptr-817)
          (go series::end))
      (setq #:elements-816 (car #:listptr-817))
      (setq #:listptr-817 (cdr #:listptr-817))
      (setq #:items-821 (car #:lst-822))
      (setq #:lst-822 (cdr #:lst-822))
      (setq #:items-826 ((lambda (s n) (cons s n)) #:elements-816 #:items-821))
      (setq #:lastcons-813 (setf (cdr #:lastcons-813) (cons #:items-826 nil)))
      (go #:ll-827)
     series::end)
    (cdr #:lst-814)))

如果需要将任意列表传递给函数，可以通过调用(nconc list list)来制作自己的循环列表，这样写起来更简单。由于您可能不想改变输入列表，因此可以改为：

(defun circularize (list)
  (let ((list (copy-list list)))
    (nconc list list)))

【参考方案2】：

我认为您的代码已经足够好。 （唯一的问题是你should not modify a quoted list）。

您需要做的就是恢复您制作的循环列表：

(defun map-circular (result-type function governing-sequence &rest reused-lists)
  "Apply `function` to successive sets of arguments in which one argument is obtained from each sequence.
The result has the length of `governing-sequence`."
  (let ((last-cells (mapcar (lambda (list)
                              (let ((cell (last list)))
                                (setf (cdr cell) list)
                                cell))
                            reused-lists)))
    (unwind-protect
         (apply #'map result-type function governing-sequence reused-lists)
      (dolist (cell last-cells)
        (setf (cdr cell) nil)))))

测试：

(defparameter l1 (list 1 2))
(defparameter l2 (list 1 2 3))
(map-circular 'list #'+ '(1 2 3 4) l1 l2)
==> (3 6 7 7)
l1
==> (1 2)
l2
==> (1 2 3)