限制对 Excel 工作表的查看访问

Posted

技术标签:

【中文标题】限制对 Excel 工作表的查看访问【英文标题】：Restrict viewing access to an Excel worksheet 【发布时间】：2019-04-25 15:42:09 【问题描述】：

我认为这将是 Excel 中一个易于使用的函数，但要实现一个简单的过程来限制对较大工作簿中特定工作表的访问，却异常困难。

有几种方法可以提示输入初始密码以打开同一工作簿的不同版本。但我想保持所有用户的工作簿相同，但限制对某些工作表的访问。肯定有密码保护功能，需要用户输入密码才能查看工作表。而不是根据不同的用户创建同一工作簿的多个版本。

我尝试了以下方法，但它没有提示输入密码来访问工作表

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

Dim MySheets As String, Response As String
Dim MySheet As Worksheet
MySheet = "COMMUNICATION"
If ActiveSheet.Name = MySheet Then
ActiveSheet.Visible = False
    Response = InputBox("Enter password to view sheet")
        If Response = "MyPass" Then
            Sheets(MySheet).Visible = True
            Application.EnableEvents = False
            Sheets(MySheet).Select
            Application.EnableEvents = True
        End If
End If
Sheets(MySheet).Visible = True
End Sub

我这样做对吗？

【问题讨论】：

“它需要 Kutools” ....不，这里的一切都是普通的 VBA。 而且 非常无用的保护（输入框上的 Ctrl+Break 将您直接带到代码中的硬编码密码）。 @MathieuGuindon。同意。这不是万无一失的保护方法。更多的是初级水平。万一没有访问权限的人点击了错误的工作表 这真的取决于你为什么要这样做。 Excel 并非旨在以这种方式工作。如果有人可以访问文件，那么他们就可以访问所有文件。您可以使用链接表来制作主工作簿的不同视图。然后每个用户角色都有自己的视图，而完整的数据仍然存在于它的当前工作表中。 【参考方案1】：

听起来，根据 cmets 的说法，这与其说是一个安全问题，不如说是一个方便问题。因此，在考虑将其实施到您的项目时请记住，如果有任何恶意意图获得未经授权的访问，这很容易被破坏。

首先，我会推荐一个通用着陆区。打开工作簿后立即显示的主工作表。为此，我们将使用Workbook_Open() 事件并从那里激活一个工作表。

如果需要，这可以是隐藏的工作表，这取决于您。

Option Explicit

Private lastUsedSheet As Worksheet

Private Sub Workbook_Open()

    Set lastUsedSheet = Me.Worksheets("MainSheet")
    Application.EnableEvents = False
    lastUsedSheet.Activate
    Application.EnableEvents = True

End Sub

接下来，我们应该决定在尝试访问新工作表时应该发生什么。在下面的方法中，一旦激活了工作表，它将自动将用户重定向回上次使用的工作表，直到密码尝试成功。

我们可以在模块范围的变量中跟踪最后使用的工作表，在本例中将命名为lastUsedSheet。每次成功更改工作表时，此变量都会自动设置为该工作表 - 这样，当有人尝试访问另一个工作表时，它会将他们重定向回前一个工作表，直到成功输入密码。

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

    On Error GoTo SafeExit

    Application.EnableEvents = False

    ' Error protection in case lastUsedSheet is nothing
    If lastUsedSheet Is Nothing Then
        Set lastUsedSheet = Me.Worksheets("MainSheet")
    End If

    ' Allow common sheets to be activated without PW
    If Sh.Name = "MainSheet" Then
        Set lastUsedSheet = Sh
        Sh.Activate
        GoTo SafeExit
    Else
        ' Temporarily send the user back to last sheet until
        ' Password has been successfully entered
        lastUsedSheet.Activate
    End If

    ' Set each sheet's password
    Dim sInputPW As String, sSheetPW As String

    Select Case Sh.Name
    Case "Sheet1"
        sSheetPW = "123456"
    Case "Sheet2"
        sSheetPW = "987654"
    End Select

    ' Create a loop that will keep prompting password
    '   until successful pw or empty string entered
    Do

        sInputPW = InputBox("Please enter password for the " & _
                "worksheet: " & Sh.Name & ".")

        If sInputPW = "" Then GoTo SafeExit

    Loop While sInputPW <> sSheetPW

    Set lastUsedSheet = Sh
    Sh.Activate

SafeExit:

    Application.EnableEvents = True
    If Err.Number <> 0 Then
        Debug.Print Time; Err.Description
        MsgBox Err.Description, Title:="Error # " & Err.Number
    End If

End Sub

旁注，禁用事件是必要的，因为您的Workbook_SheetActivate 事件将在成功更改工作表后继续触发。

防止在SaveAs1 期间更改文件类型

您可以通过限制文件保存类型来进一步防止意外删除 VBA 代码。这可以使用Workbook_BeforeSave() 事件来完成。这是一个潜在问题的原因是，保存为未启用宏的工作簿会擦除代码，这将阻止您刚刚在上面实现的密码保护功能。

首先，我们需要检查这是Save 还是SaveAs。您可以使用事件本身包含的布尔属性SaveAsUI 来完成此操作。如果这个值为True，那么它就是一个SaveAs 事件——这意味着我们需要执行额外的检查以确保文件类型不会从保存对话框中意外更改。如果值为False，那么这是正常保存，我们可以绕过这些检查，因为我们知道工作簿将保存为.xlsm类型。

经过初步检查，我们将使用Application.FileDialog().Show显示对话框。

之后，我们会检查用户是否取消了操作.SelectedItems.Count = 0或点击了保存。如果用户点击取消，那么我们只需设置Cancel = True，工作簿将不会保存。

我们继续检查用户使用此行选择的扩展类型：

If Split(fileName, ".")(UBound(Split(fileName, "."))) <> "xlsm" Then

这将用句点. 分割文件路径，并在文件名可能包含其他句点的情况下获取句点(UBound(Split(fileName, "."))) 的最后一个实例。如果扩展名与xlsm 不匹配，则中止保存操作。

最后，所有检查通过后，您可以保存文档：

Me.SaveAs .SelectedItems(1), 52

由于我们已经用上面的行保存了它，我们可以继续设置Cancel = True并退出例程。

完整代码（要放在Worksheet obj模块中）：

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

    On Error GoTo SafeExit

    If SaveAsUI Then
        With Application.FileDialog(msoFileDialogSaveAs)
            .Show
            If .SelectedItems.Count = 0 Then
                Cancel = True
            Else
                Dim fileName$
                fileName = .SelectedItems(1)
                If Split(fileName, ".")(UBound(Split(fileName, "."))) <> "xlsm" Then
                    MsgBox "You must save this as an .xlsm document. Document has " & _
                                "NOT been saved", vbCritical
                    Cancel = True
                Else
                    Application.EnableEvents = False
                    Application.DisplayAlerts = False
                    Me.SaveAs .SelectedItems(1), 52
                    Cancel = True
                End If
            End If
        End With
    Else
        Exit Sub
    End If

SafeExit:

    Application.EnableEvents = True
    Application.DisplayAlerts = True

    If Err.Number <> 0 Then
        Debug.Print Time; Err.Description
        MsgBox Err.Description, Title:="Error # " & Err.Number
    End If

End Sub

1 向PatricK 提出建议

【讨论】：

我认为我们还需要防止另存为 .xlsx 格式，因为它完全去除了所有保护宏。 好建议，@PatricK。我确信我可以使用BeforeSave() 事件快速地将一些东西放在一起。【参考方案2】：

如果您想限制对工作表的访问，您可以将其隐藏：

ActiveWorkbook.Sheets("YourWorkSheet").Visible = xlSheetVeryHidden

【讨论】：

您需要对 VBA 项目进行密码保护，以便用户无法取消隐藏工作表 您需要使用实际工具，例如 Unviewable+（无从属关系）来保护 VBA，只要研究“破解 vba 密码”的人不会在半秒内击败它。跨度> @mdialogo，我不想按照 cmets 隐藏它 @MathieuGuindon。完全同意。如前所述。这不是一种加密方法。只是这个表被限制的一个初始屏幕。大多数用户偶然点击它或只是碰碰运气。如果他们足够努力，他们就会进入，但这代表了一个不同的问题。我只是经过初步筛选【参考方案3】：

我同意 Mathieu Guindon 的观点，即任何 VBA 尝试“限制对 Excel 工作表的查看访问”都将是脆弱的，正如 Mathieu Guindon 所解释的那样。 此外，如果文件是使用 Excel 选项宏安全级别而不是最低级别打开的，则包括此在内的任何 VBA 代码都必然会失败。

不过，简单我更喜欢使用工作簿打开事件和受限工作表的工作表激活。即使在具有查看权限的用户在工作表之间切换时，使用工作簿工作表激活事件也会触发密码提示。 

Private Sub Workbook_Open()
Sheets("COMMUNICATION").Visible = xlSheetHidden
End Sub

Public ViewAccess As Boolean       'In restricted sheet's activate event
Private Sub Worksheet_Activate()
If ViewAccess = False Then
Me.Visible = xlSheetHidden
response = Application.InputBox("Password", xTitleId, "", Type:=2)
    If response = "123" Then
        Me.Visible = xlSheetVisible
        ViewAccess = True
    End If
End If
End Sub

【讨论】：

以上是关于限制对 Excel 工作表的查看访问的主要内容，如果未能解决你的问题，请参考以下文章

将 Excel 工作表中的数据插入到链接的访问表中

如何查看excel工作薄中有几个工作表

在excel中如何取消工作表的保护命令

Excel UDF 对变量工作表的范围求和

撤销excel工作表保护的方法步骤

保护 Excel 工作表 - 不可能？